省略应用转换时出现的额外 xlmns 和 xmlns:tei答案

【问题标题】：omit extra xlmns and xmlns:tei that appear when I apply my transformation省略应用转换时出现的额外 xlmns 和 xmlns:tei
【发布时间】：2012-08-29 09:26:16
【问题描述】：

我在互联网上（以及在这个论坛上）找到了很多解决这个问题的方法，但我仍然可以解决我的问题。我有这个代码：

<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:tei="http://www.tei-c.org/ns/1.0"
    exclude-result-prefixes="#default">
    <xsl:output omit-xml-declaration="yes" standalone="no" method="xml" indent="no" />

    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>

    </xsl:template>

    <xsl:template match="tei:body">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
        <back>
            <div>
                <xsl:for-each select="//tei:rs[@type='luogo']">
                    <p><xsl:value-of select="."/></p>
                </xsl:for-each>
            </div></back>
    </xsl:template>
</xsl:stylesheet>

输出是正确的，除了后面部分重复 xmlns 和 xmlns:tei 属性：

<back xmlns="" xmlns:tei="http://www.tei-c.org/ns/1.0"><div>....</div></back>

他们已经在这里了（所以我不需要“后面的”）：

<TEI xmlns="http://www.tei-c.org/ns/1.0">

我试过这样的代码：

<xsl:template match="@*|node()[not(self::*)]">
        <xsl:copy/>
    </xsl:template>

    <xsl:template match="*">
        <xsl:element name="{local-name()}">
            <xsl:apply-templates select="node()|@*"/>
        </xsl:element>
    </xsl:template>

或者这个：

<xsl:template match="*">
        <xsl:element name="{local-name()}">
            <xsl:apply-templates select="@*|*"/>
        </xsl:element>
    </xsl:template>

    <xsl:template match="tei:back">
        <xsl:attribute name="{local-name()}">
            <xsl:value-of select="."/>
        </xsl:attribute>
    </xsl:template>

我什至更改了它以使其适合我的代码，使用“tei:back”更改匹配或选择的值，它不起作用。为了使 tei 命名空间仅出现在该部分中，我必须做什么？感谢您的建议！

编辑：谢谢你的回答。我的xml代码是这样的：

<?xml version="1.0" encoding="UTF-8"?>
<?xml-stylesheet type="text/xsl" href="file:/C:/Users/User/Desktop/prova2.xsl"?>
<TEI xmlns="http://www.tei-c.org/ns/1.0">
    <teiHeader><fileDesc>
        <titleStmt>
            <title>AA</title>
        </titleStmt>
        <publicationStmt><p><!-- supply publication information --></p></publicationStmt>
        <sourceDesc>
            <bibl>AA</bibl>
        </sourceDesc>
    </fileDesc><profileDesc>
        <langUsage>
            <language ident="ita">AA</language>
            <language ident="lat">AA</language>
        </langUsage>
    </profileDesc></teiHeader>
    <text>
        <body>
            <div type="book" n="3" xml:id="L3">
                <head>AA
                </head>
                <div type="cap" n="1" xml:id="L3-01">
                    <head>AA</head>
                    <p>AA
                        <pb n="200"/>AA      
                    </p>
                </div>
            </div>
        </body>
    </text>
</TEI>

完整的输出是这样的：

<?xml-stylesheet type="text/xsl" href="file:/C:/Users/User/Desktop/prova2.xsl"?><TEI xmlns="http://www.tei-c.org/ns/1.0">
    <teiHeader><fileDesc>
        <titleStmt>
            <title>AA</title>
        </titleStmt>
        <publicationStmt><p><!-- supply publication information --></p></publicationStmt>
        <sourceDesc>
            <bibl>AA</bibl>
        </sourceDesc>
    </fileDesc><profileDesc>
        <langUsage>
            <language ident="ita">AA</language>
            <language ident="lat">AA</language>
        </langUsage>
    </profileDesc></teiHeader>
    <text>
        <body>
            <div type="book" n="3" xml:id="L3">
                <head>AA
                </head>
                <div type="cap" n="1" xml:id="L3-01">
                    <head>AA</head>
                    <p>AA
                        <pb n="200"/>AA      
                    </p>
                </div>
            </div>
        </body><back xmlns="" xmlns:tei="http://www.tei-c.org/ns/1.0"><div/></back>
    </text>
</TEI>

【问题讨论】：

为什么不使用html 命名空间？
您能告诉我们您正在使用的输入 XML 吗？谢谢！
给我一个有趣的问题 +1

标签： xml xslt namespaces

【解决方案1】：

出现问题是因为在您的输入 XML 文档中，所有元素都被指定在命名空间“http://www.tei-c.org/ns/1.0”内。但是，在您的 XSLT 中，您正在创建新元素（在 tei:body 模板中），但您没有指定新元素的名称空间。这意味着新元素，例如 back 创建时没有命名空间，因此输出 XML 包含额外的命名空间标签来表明这一点。

解决此问题的一种方法是在创建元素时指定命名空间。而不是这样做....

<back>....</back>

这样做....

<xsl:element name="back" namespace="http://www.tei-c.org/ns/1.0">....</xsl:element>

这是完整的 XSLT

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:tei="http://www.tei-c.org/ns/1.0" exclude-result-prefixes="#default">
   <xsl:output omit-xml-declaration="yes" standalone="no" method="xml" indent="no"/>

   <xsl:template match="@*|node()">
      <xsl:copy>
         <xsl:apply-templates select="@*|node()"/>
      </xsl:copy>
   </xsl:template>

   <xsl:template match="tei:body">
      <xsl:copy>
         <xsl:apply-templates select="@*|node()"/>
      </xsl:copy>
      <xsl:element name="back" namespace="http://www.tei-c.org/ns/1.0">
         <xsl:element name="div" namespace="http://www.tei-c.org/ns/1.0">
            <xsl:for-each select="//tei:rs[@type='luogo']">
               <xsl:element name="p" namespace="http://www.tei-c.org/ns/1.0">
                  <xsl:value-of select="."/>
               </xsl:element>
            </xsl:for-each>
         </xsl:element>
      </xsl:element>
   </xsl:template>
</xsl:stylesheet>

当应用于您的示例 XML 时，将输出以下内容

<TEI xmlns="http://www.tei-c.org/ns/1.0">
   <teiHeader>
      <fileDesc>
         <titleStmt>
            <title>AA</title>
         </titleStmt>
         <publicationStmt>
            <p><!-- supply publication information -->
            </p>
         </publicationStmt>
         <sourceDesc>
            <bibl>AA</bibl>
         </sourceDesc>
      </fileDesc>
      <profileDesc>
         <langUsage>
            <language ident="ita">AA</language>
            <language ident="lat">AA</language>
         </langUsage>
      </profileDesc>
   </teiHeader>
   <text>
      <body>
         <div type="book" n="3" xml:id="L3">
            <head>AA </head>
            <div type="cap" n="1" xml:id="L3-01">
               <head>AA</head>
               <p>AA 
                  <pb n="200"/>AA 
               </p>
            </div>
         </div>
      </body>
      <back>
         <div/>
      </back>
   </text>
</TEI>

【讨论】：

感谢蒂姆的解释。到目前为止，我从未在 XSLT 中处理过名称空间。 +1