XSLT- 根据匹配的节点值从其他 XML 文件复制节点

Question

您好，我有两个不同的 xml，我想合并它们，根据匹配的源和目标 xml 节点值从目标 xml 复制一个节点

第一个这样的xml：

<PRODUCTS>
  <PRODUCT>
    <NAME>PRODUCT 1</NAME>
    <MAINCATID>38</MAINCATID>
    <SUBCATID>39</SUBCATID>
  </PRODUCT>
</PRODUCTS>

第二个XML是这样的

 <CATEGORIES>
  <MAINCATEGORY>
   <MAINCATID>38</MAINCATID>
   <MAINCATNAME>CATEGORY 1</MAINCATNAME>
  </MAINCATEGORY>
  <MAINCATEGORY>
   <MAINCATID>37</MAINCATID>
   <MAINCATNAME>CATEGORY 2</MAINCATNAME>
  </MAINCATEGORY>
  <SUBCATEGORY>
   <SUBCATID>39</SUBCATID>
   <SUBCATNAME>SUB CATEGORY 1</SUBCATNAME>
  </SUBCATEGORY>
  <SUBCATEGORY>
   <SUBCATID>40</SUBCATID>
   <SUBCATNAME>SUB CATEGORY 2</SUBCATNAME>
  </SUBCATEGORY>
</CATEGORIES>

我的结果 xml 应该是这样的

<PRODUCTS>
  <PRODUCT>
    <NAME>PRODUCT 1</NAME>
    <MAINCATID>38</MAINCATID>
    <MAINCATNAME>CATEGORY 1</MAINCATNAME>
    <SUBCATID>39</SUBCATID>
    <SUBCATNAME>SUB CATEGORY 1</SUBCATNAME>
  </PRODUCT>
</PRODUCTS>

有很多这样的节点。我想根据主要和子类别 id 从第二个 xml 中获取类别名称。

您能帮忙解决一下这个 XSLT 转换吗？

Answer 1

使用 key 从另一个文档中查找数据在 XSLT 1.0 中有点笨拙，但它仍然是最好的方法，恕我直言，无论是在性能还是代码清晰度方面。试试：

XSLT 1.0

<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:variable name="lookup-source" select="document('file2.xml')" />

<xsl:key name="MAINCATID" match="MAINCATNAME" use="../MAINCATID" />
<xsl:key name="SUBCATID" match="SUBCATNAME" use="../SUBCATID" />

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="MAINCATID | SUBCATID">
    <xsl:copy-of select="."/>
    <xsl:variable name="key-name" select="local-name()"/>
    <xsl:variable name="key-value" select="."/>
    <!-- switch context to the other file for the actual lookup -->
    <xsl:for-each select="$lookup-source">
        <xsl:copy-of select="key($key-name, $key-value)" />
    </xsl:for-each>
</xsl:template>

</xsl:stylesheet>

我们在这里假设您的“第一个 xml”文档是正在处理的文档。

Answer 2

在 XSLT 中使用多个 XML 文档的关键是 document() 这是一个快速而肮脏的示例，演示了在针对 products.xml 处理模板时引入 categories.xml（根据 @michael.hor257k 的评论和一些调整）：

<?xml version="1.0" encoding="utf-8"?>    
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">    
<xsl:output indent="yes" method="xml" encoding="UTF-8"/>


<xsl:variable name="categories" select="document('categories.xml')" />


<xsl:template match="MAINCATID">
    <xsl:variable name="maincatid" select="." />
    <MAINCATID><xsl:value-of select="$maincatid" /></MAINCATID>
    <MAINCATNAME><xsl:value-of select="$categories//MAINCATEGORY[MAINCATID=$maincatid]/MAINCATNAME" /></MAINCATNAME>
</xsl:template>

<xsl:template match="SUBCATID">
    <xsl:variable name="subcatid" select="." />
    <SUBCATID><xsl:value-of select="$subcatid" /></SUBCATID>
    <SUBCATNAME><xsl:value-of select="$categories//SUBCATEGORY[SUBCATID=$subcatid]/SUBCATNAME" /></SUBCATNAME>
</xsl:template>


<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()" />
    </xsl:copy>
</xsl:template>


<xsl:template match="/">
    <xsl:apply-templates />
</xsl:template>

</xsl:stylesheet>

在此示例中，<xsl:variable name="categories" select="document('categories.xml') /> 引入了类别。现在其他模板可以通过使用$categories 变量进入您的第二个XML。这通过

来证明

<xsl:value-of select="$categories//MAINCATEGORY[MAINCATID=$maincatid]/MAINCATNAME" />

通过此示例运行您的第一个 XML（将您的第二个 XML 保存为名为“categories.xml”的文件）产生以下结果：

<PRODUCTS>
  <PRODUCT>
    <NAME>PRODUCT 1</NAME>
    <MAINCATID>38</MAINCATID>
    <MAINCATNAME>CATEGORY 1</MAINCATNAME>
    <SUBCATID>39</SUBCATID>
    <SUBCATNAME>SUB CATEGORY 1</SUBCATNAME>
  </PRODUCT>
<PRODUCTS>