如何从 XSLT 中获取未解析的实体属性值？

Question

我对 XSLT 和 XML 中未解析的实体有疑问。这是一个虚构的场景。首先我得到一个名为 doc.xml 的 XML 文件：

<?xml version="1.0" encoding="UTF-8" standalone="no"?>

<!DOCTYPE document [
<!ELEMENT document (employee)*>
<!ELEMENT employee (lastname, firstname)>
<!ELEMENT lastname (#PCDATA)>
<!ELEMENT firstname (#PCDATA)>
<!NOTATION FOO SYSTEM 'text/xml'>
<!ENTITY ATTACHMENT SYSTEM 'attach.xml' NDATA FOO>
<!ATTLIST employee
       detail ENTITY #IMPLIED>
]>
<document>
    <employee detail="ATTACHMENT">
        <lastname>Bob</lastname>
        <firstname>Kevin</firstname>
    </employee>
</document>

在这个 XML 文件中，我对元素“employee”的属性“detail”使用了一个未解析的实体 (NDATA)。 attach.xml 是：

<?xml version="1.0" encoding="UTF-8"?>

<name>Bob Kevin</name>

然后我想使用 XSLT 生成输出以及嵌入的 attach.xml。我的 XSLT 文件名为 doc.xsl：

<?xml version="1.0"?>

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
<xsl:output method="xml" indent="yes"/>

<xsl:template match="document">
<Document>
        <xsl:apply-templates select="employee"/>
</Document>
</xsl:template>

<xsl:template match="employee">
Employee is:  <xsl:value-of select="@detail"/>
</xsl:template>

</xsl:stylesheet>

最后，我使用 Xalan 2.7.1 运行：

java -jar xalan.jar -IN doc.xml -XSL doc.xsl -OUT docout.xml

输出是：

<?xml version="1.0" encoding="UTF-8"?>
<Document>
Employee is:  ATTACHMENT
</Document>

这不是我想要的。我希望输出如下所示：

<?xml version="1.0" encoding="UTF-8"?>
<Document>
Employee is:  <name>Bob Kevin</name>
</Document>

我应该如何重写 XSLT 脚本以获得正确的结果？

Answer 1

XSLT 2.0 中的解决方案：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0">
<xsl:output method="xml" indent="yes"/>

<xsl:template match="document">
<Document>
        <xsl:apply-templates select="employee"/>
</Document>
</xsl:template>

<xsl:template match="employee">
Employee is:  <xsl:value-of select=
"unparsed-text(unparsed-entity-uri(@detail))"/>
</xsl:template>

</xsl:stylesheet>

请注意以下几点：

1. XSLT 函数unparsed-text() 和unparsed-entity-uri() 的使用。

2. attach.xml 文件的文本将在输出中转义。如果您想看到它未转义，请使用 <xsl:output/> 指令的 "cdata-section-elements" 属性。

Answer 2

谢谢你，Dimitre Novatchev。根据您的回答，我在 XSLT 1.0 中得到了结果。有兴趣的可以参考http://www.xml.com/lpt/a/1243进行讨论。这是我的解决方案：

<?xml version="1.0"?>

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
<xsl:output method="xml" indent="yes"/>

<xsl:template match="document">
<Document>
        <xsl:apply-templates select="employee"/>
</Document>
</xsl:template>

<xsl:template match="employee">
Employee is: <xsl:copy-of select="document(unparsed-entity-uri(@detail))"/>
</xsl:template>

</xsl:stylesheet>

请注意上面的以下行：

 <xsl:copy-of select="document(unparsed-entity-uri(@detail))"/>