XSLT 1.0 使用 REPLACE 方法的潜在替换数量会产生 StackOverFlow 异常

Question

我尝试使用 XSLT 1.0 版将 XML 文件转换为 Json 格式，我正在使用 XSL 上的 Replace 方法进行潜在的替换。这会产生 StackOverFlowException。

Replace 方法是递归调用的，所以我遇到了这个问题。有什么解决方案可以解决这个问题吗？

    <xsl:template name="replace-string">
    <xsl:param name="text"/>
    <xsl:param name="replace"/>
    <xsl:param name="with"/>
    <xsl:choose>
      <xsl:when test="contains($text,$replace)">
        <xsl:value-of select="substring-before($text,$replace)"/>
        <xsl:value-of select="$with"/>
        <xsl:call-template name="replace-string">
          <xsl:with-param name="text" select="substring-after($text,$replace)"/>
          <xsl:with-param name="replace" select="$replace"/>
          <xsl:with-param name="with" select="$with"/>
        </xsl:call-template>
      </xsl:when>
      <xsl:otherwise>
        <xsl:value-of select="$text"/>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>

Answer 1

当您使用 libxslt 时，您可以使用 EXSLT str:replace 函数而不是递归模板，即

<xsl:stylesheet
  version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:str="http://exslt.org/strings"
  exclude-result-prefixes="str">

<xsl:template match="@* | node()">
  <xsl:copy>
    <xsl:apply-templates select="@* | node()"/>
  </xsl:copy>
</xsl:template>

<xsl:template match="text()">
  <xsl:value-of select="str:replace(., '&quot;', '\&quot;')"/>
</xsl:template>

</xsl:stylesheet>

将<data>This is a text with "quoted" parts</data> 转换为<data>This is a text with \"quoted\" parts</data>。

作为替代方案，xsltproc（使用 libxslt 的命令行工具）有一个设置 --maxdepth val : increase the maximum depth (default 3000)，如果您需要更多递归深度，我认为您可能需要增加/更改。