Delphi 中的文件搜索忽略了一些 Windows 目录

Question

我正在使用此线程 (How to Search a File through all the SubDirectories in Delphi) 中的代码递归查找文件：

procedure FindFilePattern(root:String;pattern:String);
var
  SR:TSearchRec;
begin
  root:=IncludeTrailingPathDelimiter(root);
  if FindFirst(root+'*.*',faAnyFile,SR) = 0 then
  begin
      repeat
          Application.ProcessMessages;
          if ((SR.Attr and faDirectory) = SR.Attr ) and (pos('.',SR.Name)=0) then
             FindFilePattern(root+SR.Name,pattern)
          else
          begin
           if pos(pattern,SR.Name)>0 then Form1.ListBox1.Items.Add(Root+SR.Name);
          end;
      until FindNext(SR)<>0;
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  FindFilePattern('C:\','.exe');
end;

它正在工作，但由于某种原因它忽略了目录 Program Files、Program Files (x86) 和 Users。不幸的是，我正在搜索的文件在这些文件夹中。有人知道为什么会这样吗？

任何提示都会非常有帮助，

谢谢

Answer 1

您的应用程序需要以提升的权限运行，才能访问您所说的子目录中的某些子目录。作为临时测试，运行“以管理员身份”来验证这一点。如果这确实是您的情况，那么您应该添加一个清单以在启动时要求提升。

Delphi 的较新版本已内置此功能。在项目选项下，转到“应用程序”页面，然后选中“启用管理员权限”。当然，这是使用 IDE 的快捷方式，您应该考虑编写自己的自定义清单，尤其是在运行没有此选项的旧版 Delphi 时。

Answer 2

就像 Jerry Dodge 提到的那样，担保权肯定是您可能需要考虑的一件事。您的代码可能需要以管理员身份运行才能访问各种系统目录和属于其他用户的目录。在大多数情况下，简单地枚举您提到的目录不需要提升权限。但是如果你发现你遇到了这样的目录，你可以：

1. 将 UAC 清单添加到请求提升的应用中

2. 将您的枚举代码移动到单独的进程或 COM 对象中，然后您可以在需要时从未提升的进程提升运行。

但除此之外，您复制的FindFilePattern() 程序一开始也执行错误。它是：

1. 比较文件属性不正确。如果条目是一个文件，或者是一个带有 NO ATTRIBUTES 的目录，则表达式 (SR.Attr and faDirectory) = SR.Attr ) 将为真。遇到带有系统、压缩、索引等属性的目录并不少见。

2. 比较文件名不正确。对于根本不包含. 字符的所有文件和目录，表达式(pos('.',SR.Name)=0) 将为真。几乎所有文件都有.，甚至目录也可以有.。处理目录时，您需要仅忽略特殊的. 和.. 目录条目，而不是任何包含. 的条目。

3. 更糟糕的是，#1 和 #2 的组合共同作用允许将具有属性的目录和包含 . 的目录视为文件而不是目录。代码通常无法正确处理目录，更不用说递归了。

4. 泄露所有搜索句柄。如果FindFirst() 成功，则必须调用FindClose()，而不管FindNext()。

试试类似的方法：

uses
  SysUtils, Masks;

procedure FindFilePattern(root: String; pattern: String);
var
  SR: TSearchRec;
begin
  root := IncludeTrailingPathDelimiter(root);
  if FindFirst(root + '*.*', faAnyFile, SR) = 0 then
  try
    repeat
      Application.ProcessMessages;
      if (SR.Attr and faDirectory) <> 0 then
      begin
        if (SR.Name <> '.') and (Sr.Name <> '..') then
          FindFilePattern(root + SR.Name, pattern);
      end else
      begin
        if MatchesMask(SR.Name, pattern) then
          Form1.ListBox1.Items.Add(Root + SR.Name);
      end;
    until FindNext(SR) <> 0;
  finally
    FindClose(SR);
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  FindFilePattern('C:\', '*.exe');
end;