如何在 Fortran 90 中向动态数组添加新元素

Question

当我最初无法预测数组的确切大小时，我需要在 Fortran 90 中使用动态数组。所以我写了一个代码，每次新元素添加到数组末尾时，它都应该扩展可分配数组：

  subroutine DArray()

  double precision, dimension(:), allocatable :: list

  allocate(list(1))

  list(1) = 1.1

  call AddToList(list, 2.2)
  call AddToList(list, 3.2)
  call AddToList(list, 4.2)
  call AddToList(list, 5.2)

  print *, list(1)
  print *, list(2)
  print *, list(3)
  print *, list(4)
  print *, list(5)


  end



  subroutine AddToList(list, element)

  double precision :: element
  double precision, dimension(:), allocatable :: list
  double precision, dimension(:), allocatable :: clist

  if(allocated(list)) then
    isize = size(list)
    allocate(clist(isize+1))
    do i=1,isize
        clist(i) = list(i)
    end do
    clist(i+1) = element

    deallocate(list)
    allocate(list(isize+1))

    do i=1,isize+1
        list(i) = clist(i)
    end do

    deallocate(clist)

  end if


  end

那么有人看看我是否在这里遗漏了什么吗？

---

由francescalus解决。

双精度动态数组的工作代码是：

  module DynamicalArrays

  contains

      subroutine AddToList(list, element)

          IMPLICIT NONE

          integer :: i, isize
          double precision, intent(in) :: element
          double precision, dimension(:), allocatable, intent(inout) :: list
          double precision, dimension(:), allocatable :: clist


          if(allocated(list)) then
              isize = size(list)
              allocate(clist(isize+1))
              do i=1,isize          
              clist(i) = list(i)
              end do
              clist(isize+1) = element

              deallocate(list)
              call move_alloc(clist, list)

          else
              allocate(list(1))
              list(1) = element
          end if


      end subroutine AddToList


  end module DynamicalArrays

可以从中填充数组的演示子程序是：

  subroutine UserDArrayTest()

  use DynamicalArrays


  integer :: i
  double precision, dimension(:), allocatable :: list
  double precision :: temp

  temp = 0.1
  do i=1,10
    temp = temp+1
    call AddToList(list, temp)
  end do

  do i=1,10
    print *, i, list(i)
  end do


  end

请注意，最好将模块代码保存在单独的文件中，但我也发现当模块代码高于主程序和子程序代码时它可以工作。

Answer 1

我怀疑，看着一个人工制品，你注意到了这个问题 - 但很快就继续前进。

对我来说可疑的线是：

    allocate(clist(isize+2))

为什么不是新尺寸isize+1？我猜你试过了，但是程序失败了。

了解程序失败（可能崩溃）的原因是您没有得到正确结果的关键。仔细查看循环（为清楚起见，删除了打印语句）。

do i=1,isize
    clist(i) = list(i)
end do
clist(i+1) = element

您想说“将所有元素从列表复制到 clist，然后附加元素”。哪个是对的。不过

do i=1,isize
    clist(i) = list(i)
end do
! Here, i=isize+1
clist(i+1) = element
! Which means
! clist(isize+2) = element.

总之，在循环之后，循环索引变量没有它在最终迭代中的值。

Answer 2

我知道这个问题很老了，但我最近不得不构建这样一个子程序，我发现，从Fortran2003开始，有一个漂亮的一行：

    SUBROUTINE append_int(vec, val)
    !***********************************************************************
    !> \brief Appends val in vec if not already present
    !> \date 05 2020
    !***********************************************************************
    INTEGER, DIMENSION(:), ALLOCATABLE, INTENT(INOUT)    :: vec
    INTEGER, INTENT(IN)                                  :: val

    ! Remove this test if you don't mind not having unique values
    IF (.NOT. ANY(vec .EQ. val)) THEN
        vec = [vec, val]
    END IF

    END SUBROUTINE

您的数组将自动以适当的大小重新分配。 此外，您可以为 Reals 生成等效的例程，用于将数组附加到另​​一个...，然后将它们全部包装在一个接口中，以便您始终可以调用相同的子例程，无论您的数据类型如何。