错误解析 - 在数据库中插入值文本框

Question

我有一个 ASP.NET 表单，它有两个文本框和一个标签，用户只在最后一个文本框中输入到期日期，而如果用户点击客户所在的转发器内的另一个按钮，其他的会自动插入找到代码和公司名称。

问题是我创建了一个类来进行插入：我使用存储过程进行插入，并使用查询参数化。

当我解析代码和日期时，它会给我 0 和一个默认日期，而我的目标是将它们插入到数据库中的表中，然后将其显示在中继器中。

附：我补充说，为了读取数据，我有另一个类和另一个存储过程，并且我有一些值在另一个表中（代码和公司名称）。

这是方法：

Public Sub INSERT_EXP_DATE_TABLE()

    Dim id_customer As Integer
    Dim exp_date As Date

    Try
        cmd.Connection = cn
        cmd.CommandType = CommandType.StoredProcedure
        MyParm = cmd.Parameters.Add("@COD_CUSTOMER", SqlDbType.Int)
        If (Integer.TryParse(txt_COD_CUSTOMER.Text, id_customer)) Then

            MyParm.Value = id_customer
        Else
            MsgBox("customer not found", vbCritical)
        End If

        MyParm = cmd.Parameters.Add("@COMPANY_NAME", SqlDbType.NVarChar)
        MyParm.Value = lbl_COMPANY_NAME.Text.ToString
        MyParm = cmd.Parameters.Add("@EXP_DATE", SqlDbType.Date)
        If (Date.TryParse(txt_EXP_DATE.Text, exp_date)) Then

            MyParm.Value = exp_date
        Else
            MsgBox("Exp Date not found", vbCritical)
        End If

        cmd.CommandText = "LST_INSERT_TABLE_01"
        cmd.Connection.Open()
        cmd.ExecuteNonQuery()
        MsgBox("Date registred", vbInformation)
    Catch ex As Exception
        MsgBox(ex.Message)

    Finally
        cn.Close()
    End Try

End Sub

这是存储过程：

@ID_CUSTOMER int,
@COMPANY_NAME varchar(50),
@EXP_DATE date, 

AS

BEGIN
INSERT INTO TABLE
                (
                ID_CUSTOMER,
                COMPANY_NAME,
                EXP_DATE,
                
                )

                
 VALUES(
 
 @ID_CUSTOMER,
 @COMPANY_NAME,
@EXP_DATE,
 
 
 )
END

Answer 1

将您的连接保持在使用它的方法的本地。连接使用非托管资源，因此它们包含一个释放这些资源的.Dispose 方法。为确保数据库对象已关闭和处置，请使用 Using...End Using 块。

在开始创建数据库对象之前是否进行解析。退出 sub 以便用户有机会纠正问题。

附注：我不认为消息框可以在 asp.net 应用程序中使用。

您将公司名称参数设置为NVarChar，但您的存储过程将其声明为VarChar。哪个是正确的？

没有必要在 .Text 属性上调用 .ToString。 .Text 属性已经是 String。

您提供了一个名为 "@COD_CUSTOMER" 的参数，但您的存储过程没有这样的参数。

Public Sub INSERT_EXP_DATE_TABLE()
    Dim id_customer As Integer
    If Not Integer.TryParse(txt_COD_CUSTOMER.Text, id_customer) Then
        MsgBox("Please enter a valid number.", vbCritical)
        Exit Sub
    End If

    Dim exp_date As Date
    If Not Date.TryParse(txt_EXP_DATE.Text, exp_date) Then
        MsgBox("Please enter a valid date.")
        Exit Sub
    End If

    Using cn As New SqlConnection("Your connection string"),
                cmd As New SqlCommand("LST_INSERT_TABLE_01", cn)
        cmd.CommandType = CommandType.StoredProcedure
        With cmd.Parameters
            .Add("@ID_CUSTOMER", SqlDbType.Int).Value = id_customer
            .Add("@COMPANY_NAME", SqlDbType.VarChar, 50).Value = lbl_COMPANY_NAME.Text
            .Add("@EXP_DATE", SqlDbType.Date).Value = exp_date
        End With
        Try
            cn.Open()
            cmd.ExecuteNonQuery()
        Catch ex As Exception
            MsgBox(ex.Message)
        End Try
    End Using
End Sub

Answer 2

   {
       
       string CN = Interaction.InputBox("Enter Company Name","Customer","",-1,-1);
       string Cname =  Interaction.InputBox("Enter Customer Name", "Customer", "", -1, -1);
        SqlConnection con = new SqlConnection(@"Data Source=Adnan;Initial Catalog=Production;Integrated Security=True");
        con.Open();
        SqlCommand cmd = new SqlCommand("INSERT INTO hello(Company_Name,Customer_name ) VALUES ( @Company_Name,@Customer_name )");
        cmd.Connection = con;
        cmd.Parameters.Clear();
        cmd.Parameters.AddWithValue("@Company_Name", CN.ToString() );
        cmd.Parameters.AddWithValue("@Customer_name", Cname.ToString());
    }