使用 Cython 将结构从 C 返回到 Python

Question

我正在尝试将一个结构从一个 c 文件传回我的 Python。假设我有一个像这样的文件 pointc.c：

typedef struct Point {
    int x;
    int y;
} Point;

struct Point make_and_send_point(int x, int y);

struct Point make_and_send_point(int x, int y) {
    struct Point p = {x, y};
    return p;
}

然后我像这样设置一个 point.pyx 文件：

"# distutils: language = c"
# distutils: sources = pointc.c

cdef struct Point:
    int x
    int y

cdef extern from "pointc.c":
    Point make_and_send_point(int x, int y)

def make_point(int x, int y):
    return make_and_send_point(x, y) // This won't work, but compiles without the 'return' in-front of the function call

如何将返回的结构放入我的 Python 中？这种事情只能通过在 Cython 中创建一个结构并通过引用 void c 函数来发送吗？

作为参考，我的 setup.py 是：

from distutils.core import setup, Extension
from Cython.Build import cythonize

setup(ext_modules = cythonize(
      "point.pyx",
      language="c"
     )
)

Answer 1

大多数情况下，您会编写某种包含 c 级结构的包装类，例如：

# point.pyx
cdef extern from "pointc.c":
    ctypedef struct Point:
        int x
        int y
    Point make_and_send_point(int x, int y)

cdef class PyPoint:
    cdef Point p

    def __init__(self, x, y):
        self.p = make_and_send_point(x, y)

    @property
    def x(self):
       return self.p.x

    @property
    def y(self):
        return self.p.y

使用中

>>> import point
>>> p = point.PyPoint(10, 10)
>>> p.x
10

Answer 2

Cython 给定结构的默认行为是将其转换为 Python 字典，这对您来说可能已经足够了。 （但这仅适用于由简单类型组成的结构）。

这不起作用有几个原因。首先，您应该从headers 中执行cdef extern from，而不是源文件，否则您会收到有关多个定义的错误（我认为这只是创建最小示例时的错误）。其次，您需要将 Point 的定义放在您的 cdef extern 块中：

cdef extern from "pointc.h":
    cdef struct Point:
        int x
        int y

如果您不这样做，那么 Cython 会为您的结构 (__pyx_t_5point_Point) 创建一个不匹配的内部名称，该名称与 C 函数签名不匹配，因此会失败。

修正此问题后，您将获得将结构体转换为字典的正确默认行为。 （这应该双向工作 - 您可以将字典转换回结构）。如果这不是您想要的，请遵循@chrisb 的回答