ASM：Seg 循环故障，不确定原因 [重复]

Question

我在 NASM x86 中编写了以下程序，但是当我尝试运行它时似乎得到的只是段错误（尝试打印时）和停止打印时的无限循环。代码成功调用printNumber一次，然后出现段错误；因此，我被引导相信这是在循环的第二次迭代中发生的事情。我在这里想念什么？我已将 cmets 添加到我的源代码中以解释发生了什么，但我不明白为什么这会为应该是一个简单程序的程序抛出段错误（目前无法访问 valgrind 或 gdb）。

这是输出：

0Segmentation fault: 11

..这是我写的小程序。我在这里没有看到什么？

SECTION .data
    arraylen dd 10
    num db 0
    farewell: db "Blah"
SECTION .bss
    array resq 8

SECTION .text
    global start

start:
    call fillArr
    mov rax, 0x02000001
    mov rdi, 0
    syscall

printNum:
    mov rsi, num
    mov rdx, 2
    call print
    ret

fillArr:
    lea rsi, [rel array] ; needed for 64 bit on mac
    xor rcx, rcx ; make this 0
    arrayloop:
        mov [rsi+rcx*8], rcx ; array element rcx updated with value
        mov rbx, [rsi + rcx*8] ; grab value at index we just filled

        add rbx, 48 ; now offset number by 48 to make it ascii'able
        mov [rsi+rcx*8], rbx ; overwritten the value we saw as it's ascii
        mov [rel num], rbx ; update storage var
        call printNum ; print
        inc rcx ; we don't need this anymore
        cmp rcx, 4
        jne arrayloop

    mov rsi, farewell
    mov rdx, 4
    call print
    ret

print:
    mov rax, 0x02000004
    mov rdi, 1
    syscall
    ret

Answer 1

从printNum调用时问题就在这里：

print:
    mov rax, 0x02000004
    mov rdi, 1
    syscall
    ret

正如 @MichaelPrefetch 和 @PeterCordes 在 cmets syscall clobbers rcx 和 r11 中提到的那样。请参阅also（这是一个带有 linux 标记的答案，但在这方面，内核行为与 x86-64 中的 MacOS 相同）。如果您对 under the hood 的工作原理感到好奇，那么在 syscall 之后不使用调试器 rcx 单步执行将包含其返回地址，这将是您的程序下一条指令（在本例中为 ret）。

由于您的 arrayloop 逻辑之后依赖于 rcx，这将在此行中出现 EXC_BAD_ACCESS 失败：

arrayloop:
    mov [rsi+rcx*8], rcx ; array element rcx updated with value

可能的修复可能如下所示：

print:
    mov rax, 0x02000004
    mov rdi, 1
    push rcx
    syscall
    pop rcx
    ret

将 rcx 值保留在堆栈上，并在 syscall 之后立即恢复其值。

作为一个替代方案，@PeterCordes 建议重构循环以完全不依赖 rcx。还有很多剩余的寄存器可供选择（除了前面提到的 r11 和 rax,rdx 用于syscall 返回值）。