NASM 32 位：printf 打印寄存器的内容

Question

我是组装新手。对于遵循我所期望的简单代码，我有不同的输出。每次调用printf 之前，eax 的内容都会向右移动某个数字。我究竟做错了什么？谢谢。

代码：

;file name : testing.asm
;assemble and link with:
;nasm -f elf testing.asm && gcc -m32 -o testing testing.o
extern  printf      ; the C function, to be called

SECTION .data       ; Data section, initialized variables

    a:  dd  15  ; int a=15
    str:    db "content in eax=%d", 10, 0 

SECTION .text       ; Code section.

    global main     ; the standard gcc entry point
main:               ; the program label for the entry point
    mov     ebp, esp
    mov     eax, [a]    ; put a from store into register

    shr     eax, 1      ; eax content should be 15>>1 = 7
    push    eax     
    push    dword str   ; string to be printed
    call    printf      ; printf(str,content_of_eax)

    shr     eax, 2
    push    eax         ; eax content should be 7>>2 = 1
    push    dword str   
    call    printf      ; printf(str,content_of_eax)    

    shr     eax, 1  
    push    eax         ; eax content should be 1>>1 = 0
    push    dword str   
    call    printf      ; printf(str,content_of_eax)

    mov     esp, ebp    ; takedown stack frame
    mov     eax, 0      ; normal, no error, return value
    ret                 ; return

输出：

content in eax=7
content in eax=4
content in eax=8

预期输出：

content in eax=7
content in eax=1
content in eax=0

Answer 1

这个答案似乎不是一个好的解决方案，由于下面的讨论，我目前保留它

---

就像其他人所说，printf 会将其结果返回给 eax。 printf 的结果是写入的字节数。

由于您将shr 操作的结果推送到堆栈，您可以使用pop 再次检索它们，如下所示：

shr     eax, 1      ; eax content should be 15>>1 = 7
push    eax    
push    dword str   ; string to be printed
call    printf      ; printf(str,content_of_eax)

pop     eax 
pop     eax 
shr     eax, 2
push    eax         ; eax content should be 7>>2 = 1
push    dword str   
call    printf      ; printf(str,content_of_eax)  

# and so on ...

Answer 2

在您的数据部分中，您可以只对a 使用等号，因为您只使用该变量一次并且不更改它（我将其称为value）。

    fmt db "content in eax=%d",0xa,0
    value equ 15

在主函数中，我很确定（如果我错了，请纠正我）你应该在用堆栈指针更新它之前保存基指针。

main:
        push ebp
        mov ebp, esp

现在您可以创建一个局部变量来存储您正在处理的当前值。

sub esp, 4

在每次调用printf 之前，您只需从那里继续获取、移动和存储堆栈中的值。

mov eax, value          ; move 15 into eax  
shr eax, 1              ; make first shift
mov dword[ebp-4], eax   ; store result in local variable

push eax                ; eax = 7
push fmt
call printf             
add esp, 8              ; clean eax & fmt off the stack

mov eax, [ebp-4]        ; fetch last shift result from variable
shr eax, 2              ; make second shift
mov dword[ebp-4], eax   ; store result back in variable

push eax                ; eax = 1
push fmt
call printf             
add esp, 8              

mov eax, [ebp-4]        ; fetch last shift result from variable
shr eax, 1              ; make last shift

push eax                ; eax = 0
push fmt
call printf             
add esp, 8

add esp, 4              ; clean local variable

然后记住，在您返回之前，当您释放堆栈帧时，您还恢复（弹出）基指针。

mov esp, ebp
pop ebp

这应该输出：

content in eax=7
content in eax=1
content in eax=0

Answer 3

printf 在eax 中返回其结果，原始值丢失。

您应该从[a] 重新加载它，或者使用在函数调用之间保存的寄存器，例如esi，但您也应该保存它并在返回给调用者之前恢复它。您应该在每次调用后使用add esp,8 弹出传递给printf 的参数，以保持堆栈帧一致。

Answer 4

请记住，printf 将返回传输到输出的字符数。所以当你这样做时：

call    printf      ; printf(str,content_of_eax)

shr     eax, 2

您实际上是从 printf 转移结果：

• “eax=7\n 中的内容”是 17 个字符，因此除以 2 得到：17 / 4 = 4

您需要在移位之前保存值（在保留的寄存器中、堆栈中或内存中）。