NASM 引导加载程序中的 jmp $

Question

我试图从Bootloader 编写引导加载程序。写的代码是

BITS 16

start:
    mov ax, 07C0h       ; Set up 4K stack space after this bootloader
    add ax, 288     ; (4096 + 512) / 16 bytes per paragraph
    mov ss, ax
    mov sp, 4096

    mov ax, 07C0h       ; Set data segment to where we're loaded
    mov ds, ax


    mov si, text_string ; Put string position into SI
    call print_string   ; Call our string-printing routine

    jmp $           ; Jump here - infinite loop!


    text_string db 'This is my cool new OS!', 0


print_string:           ; Routine: output string in SI to screen
    mov ah, 0Eh     ; int 10h 'print char' function

.repeat:
    lodsb           ; Get character from string
    cmp al, 0
    je .done        ; If char is zero, end of string
    int 10h         ; Otherwise, print it
    jmp .repeat

.done:
    ret


    times 510-($-$$) db 0   ; Pad remainder of boot sector with 0s
    dw 0xAA55       ; The standard PC boot signature

我不明白我们为什么要写 jmp$。通过编写 jmp$ 它进入一个无限循环。所以，进入无限循环后，最后两行

times 510-($-$$) db 0   ; Pad remainder of boot sector with 0s
    dw 0xAA55       ; The standard PC boot signature

永远不会被执行。

此外，我们为什么要在 ax 中添加 288？

Answer 1

最后两个语句不是可执行语句，它们是一种伪指令或汇编指令。在这里，它们用于组装目标代码而不是一些可执行指令，并确保引导扇区为 512 字节。

jmp $ 然而是一个可执行指令，并且会在加载器加载它之后运行。而最后两行是由汇编器在将汇编代码汇编成目标文件时使用（而不是执行）的。

Answer 2

$ 是当前指令的地址，所以jmp $ 正在循环到自己。这通常是针对致命错误执行的。

这里的加载器是不完整的，所以它正在输出一条消息然后循环。 “循环”指令[希望]将被实际代码[待添加]替换。

用 db 或 dw 伪操作定义的东西是 data 的定义，并且是 not 可执行指令 [通常——除非你需要特殊指令汇编器不知道]。

因此，如果没有无限循环，您将尝试执行text_string: 处的数据，这会产生未定义/意外的结果，更不用说尝试执行引导块的最后部分了。

---

288 偏移量...

引导加载到地址0x07C00。它试图在位置(0x07C00 + 4096 + 512) --> 0x8E00 设置它的堆栈段。但是，它试图将其放入段寄存器中，因此该值必须右移 4 位。 0x07C0已经移位，288 是(4096 + 512) >> 4 或0x0120。 SS 的最终值为0x07C0 + 0x0120 --> 0x08E0 [地址0x8E00]

这似乎是错误的（即算术不匹配），但sp 寄存器设置为4096，因此ss:sp 的最后存放位置是地址0x9E00。

在 8086 实模式寻址中，所有地址都使用段寄存器和一些偏移量。最终地址为：address = (segreg << 4) + offset。这是由硬件在以某种方式访问​​内存的每条指令上完成的。

当您在代码中跳转时，您使用CS [代码段] 寄存器。数据访问使用DS [数据段] 寄存器。和堆栈访问（例如push/pop 或%sp 相对，使用SS [堆栈段] 寄存器。还有一个ES [额外段] 寄存器用于字符串指令。