我认为在抽象生成器的 monad 中进行需要随机数的计算是最干净的事情。下面是该代码的样子：
我们将把 StdGen 实例放在一个状态单子中，然后在状态单子的 get 和 set 方法上提供一些糖来给我们随机数。
首先，加载模块：
import Control.Monad.State (State, evalState, get, put)
import System.Random (StdGen, mkStdGen, random)
import Control.Applicative ((<$>))
（通常我可能不会指定导入，但这很容易理解每个函数的来源。）
然后我们将定义我们的“需要随机数的计算”单子；在这种情况下，State StdGen 的别名称为R。 （因为“Random”和“Rand”已经有别的意思了。）
type R a = State StdGen a
R 的工作方式是：定义一个需要随机数流的计算（一元“动作”），然后使用runRandom“运行”它：
runRandom :: R a -> Int -> a
runRandom action seed = evalState action $ mkStdGen seed
这需要一个动作和一个种子，并返回动作的结果。就像平常的evalState、runReader等一样
现在我们只需要 State monad 周围的糖。我们使用get 来获取StdGen，我们使用put 来安装新状态。这意味着，要获得一个随机数，我们会这样写：
rand :: R Double
rand = do
gen <- get
let (r, gen') = random gen
put gen'
return r
我们得到随机数生成器的当前状态，用它得到一个新的随机数和一个新的生成器，保存随机数，安装新的生成器状态，返回随机数。
这是一个可以用runRandom运行的“动作”，我们来试试吧：
ghci> runRandom rand 42
0.11040701265689151
it :: Double
这是一个纯函数，所以如果你用同样的参数再次运行它，你会得到同样的结果。杂质留在您传递给 runRandom 的“动作”中。
无论如何，你的函数需要成对的随机数，所以让我们编写一个动作来产生一个随机数pair：
randPair :: R (Double, Double)
randPair = do
x <- rand
y <- rand
return (x,y)
使用 runRandom 运行它，您会看到这对中的两个不同的数字，正如您所期望的那样。但请注意，您不必提供带有参数的“rand”；那是因为函数是纯粹的，但“rand”是一个动作，它不必是纯粹的。
现在我们可以实现您的normals 函数。 boxMuller 就像你在上面定义的那样，我只是添加了一个类型签名，这样我就可以理解发生了什么而无需阅读整个函数：
boxMuller :: Double -> Double -> (Double, Double) -> Double
boxMuller mu sigma (r1,r2) = mu + sigma * sqrt (-2 * log r1) * cos (2 * pi * r2)
在实现了所有辅助函数/动作之后，我们终于可以编写normals，这是一个包含 0 个参数的动作，它返回一个（延迟生成的）正态分布双精度数的无限列表：
normals :: R [Double]
normals = mapM (\_ -> boxMuller 0 1 <$> randPair) $ repeat ()
如果你愿意，你也可以写得不那么简洁：
oneNormal :: R Double
oneNormal = do
pair <- randPair
return $ boxMuller 0 1 pair
normals :: R [Double]
normals = mapM (\_ -> oneNormal) $ repeat ()
repeat () 为单子动作提供了一个无限的无源流来调用函数（这就是使法线的结果无限长的原因）。我最初写了[1..]，但我重写了它以从程序文本中删除无意义的1。我们不是对整数进行操作，我们只需要一个无限列表。
不管怎样，就是这样。要在实际程序中使用它，您只需在 R 动作中完成需要随机法线的工作：
someNormals :: Int -> R [Double]
someNormals x = liftM (take x) normals
myAlgorithm :: R [Bool]
myAlgorithm = do
xs <- someNormals 10
ys <- someNormals 10
let xys = zip xs ys
return $ uncurry (<) <$> xys
runRandom myAlgorithm 42
适用于编程一元动作的常用技术；在R 中尽可能少地保留您的应用程序，这样事情就不会太乱了。
哦，还有另一件事：懒惰可以干净地“泄漏”到 monad 边界之外。这意味着你可以写：
take 10 $ runRandom normals 42
它会起作用的。