cmake CheckCSourceCompiles 将预处理器定义传递给 armlink答案

【问题标题】：cmake CheckCSourceCompiles passes preprocessor-definitions to armlinkcmake CheckCSourceCompiles 将预处理器定义传递给 armlink
【发布时间】：2018-09-12 20:27:03
【问题描述】：

我正在尝试检查 armcc 中的 thread_local（作为 __thread 或 __declspec(thread) 提供）功能。

CHECK_C_SOURCE_COMPILES("int main(){ static __thread int num; return 0;}" GCC_THREAD_LOCAL_AVAILABLE)

使用我的armcc版本，我可以在上面的cmake命令中编译源代码而没有任何错误。

但 cmake 未能通过此测试并显示以下日志：

Building C object CMakeFiles/cmTC_293ce.dir/src.o
/opt/ARM/DS-5//bin/armcc   -DGCC_THREAD_LOCAL_AVAILABLE  -o CMakeFiles/cmTC_293ce.dir/src.o   -c /devdisk/users/gjha/code/aepe15_dryos_2nd/CMakeFiles/CMakeTmp/src.c
"/devdisk/users/gjha/code/aepe15_dryos_2nd/CMakeFiles/CMakeTmp/src.c", line 1: Warning:  #177-D: variable "num" was declared but never referenced
  int main(){ static __thread int num; return 0;}
                                  ^
/devdisk/users/gjha/code/aepe15_dryos_2nd/CMakeFiles/CMakeTmp/src.c: 1 warning, 0 errors
Linking C executable cmTC_293ce.elf
/opt/cmake394/bin/cmake -E cmake_link_script CMakeFiles/cmTC_293ce.dir/link.txt --verbose=1
/opt/ARM/DS-5/bin/armlink  -DGCC_THREAD_LOCAL_AVAILABLE    CMakeFiles/cmTC_293ce.dir/src.o  -o cmTC_293ce.elf
Warning: L3910W: Old syntax, please use '-d'.
Fatal error: L3900U: Unrecognized option '-GCC_THREAD_LOCAL_AVAILABLE'.
Finished: 0 information, 1 warning, 0 error and 1 fatal error messages.
gmake[1]: *** [cmTC_293ce.elf] Error 1

这里的问题是，cmake 将宏定义-DGCC_THREAD_LOCAL_AVAILABLE 溢出到链接器命令中并且armlink 失败。

请指导我如何避免这个宏定义溢出。

ARMCC version: 5.04
cmake version: 3.9.4

对于 GCC，这个问题不会发生，gnu-ld 只是忽略命令行中的宏定义。

【问题讨论】：

CHECK_C_SOURCE_COMPILES 的第二个参数只是一个变量名。那么，-DGCC_THREAD_LOCAL_AVAILABLE 编译选项的来源是什么？你是设置CMAKE_REQUIRED_DEFINITIONS 变量还是什么？
没有 cmake 从命令中发明这个宏定义。

标签： c++ cmake armcc

【解决方案1】：

模块CMake/Modules/CheckCXXSourceCompiles.cmake的来源如下：

# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
# file Copyright.txt or https://cmake.org/licensing for details.

#[=======================================================================[.rst:
CheckCXXSourceCompiles
----------------------

Check if given C++ source compiles and links into an executable.

.. command:: check_cxx_source_compiles

  ::

    check_cxx_source_compiles(code resultVar [FAIL_REGEX regex1 [regex2...]])

  Check that the source supplied in ``code`` can be compiled as a C++ source
  file and linked as an executable (so it must contain at least a ``main()``
  function). The result will be stored in the internal cache variable specified
  by ``resultVar``, with a boolean true value for success and boolean false for
  failure. If ``FAIL_REGEX`` is provided, then failure is determined by
  checking if anything in the output matches any of the specified regular
  expressions.

  The underlying check is performed by the :command:`try_compile` command. The
  compile and link commands can be influenced by setting any of the following
  variables prior to calling ``check_cxx_source_compiles()``:

  ``CMAKE_REQUIRED_FLAGS``
    Additional flags to pass to the compiler. Note that the contents of
    :variable:`CMAKE_CXX_FLAGS <CMAKE_<LANG>_FLAGS>` and its associated
    configuration-specific variable are automatically added to the compiler
    command before the contents of ``CMAKE_REQUIRED_FLAGS``.

  ``CMAKE_REQUIRED_DEFINITIONS``
    A :ref:`;-list <CMake Language Lists>` of compiler definitions of the form
    ``-DFOO`` or ``-DFOO=bar``. A definition for the name specified by
    ``resultVar`` will also be added automatically.

  ``CMAKE_REQUIRED_INCLUDES``
    A :ref:`;-list <CMake Language Lists>` of header search paths to pass to
    the compiler. These will be the only header search paths used by
    ``try_compile()``, i.e. the contents of the :prop_dir:`INCLUDE_DIRECTORIES`
    directory property will be ignored.

  ``CMAKE_REQUIRED_LIBRARIES``
    A :ref:`;-list <CMake Language Lists>` of libraries to add to the link
    command. These can be the name of system libraries or they can be
    :ref:`Imported Targets <Imported Targets>` (see :command:`try_compile` for
    further details).

  ``CMAKE_REQUIRED_QUIET``
    If this variable evaluates to a boolean true value, all status messages
    associated with the check will be suppressed.

  The check is only performed once, with the result cached in the variable
  named by ``resultVar``. Every subsequent CMake run will re-use this cached
  value rather than performing the check again, even if the ``code`` changes.
  In order to force the check to be re-evaluated, the variable named by
  ``resultVar`` must be manually removed from the cache.

#]=======================================================================]

include_guard(GLOBAL)

macro(CHECK_CXX_SOURCE_COMPILES SOURCE VAR)
  if(NOT DEFINED "${VAR}")
    set(_FAIL_REGEX)
    set(_key)
    foreach(arg ${ARGN})
      if("${arg}" MATCHES "^(FAIL_REGEX)$")
        set(_key "${arg}")
      elseif(_key)
        list(APPEND _${_key} "${arg}")
      else()
        message(FATAL_ERROR "Unknown argument:\n  ${arg}\n")
      endif()
    endforeach()

    set(MACRO_CHECK_FUNCTION_DEFINITIONS
      "-D${VAR} ${CMAKE_REQUIRED_FLAGS}")
    if(CMAKE_REQUIRED_LIBRARIES)
      set(CHECK_CXX_SOURCE_COMPILES_ADD_LIBRARIES
        LINK_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
    else()
      set(CHECK_CXX_SOURCE_COMPILES_ADD_LIBRARIES)
    endif()
    if(CMAKE_REQUIRED_INCLUDES)
      set(CHECK_CXX_SOURCE_COMPILES_ADD_INCLUDES
        "-DINCLUDE_DIRECTORIES:STRING=${CMAKE_REQUIRED_INCLUDES}")
    else()
      set(CHECK_CXX_SOURCE_COMPILES_ADD_INCLUDES)
    endif()
    file(WRITE "${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/src.cxx"
      "${SOURCE}\n")

    if(NOT CMAKE_REQUIRED_QUIET)
      message(STATUS "Performing Test ${VAR}")
    endif()
    try_compile(${VAR}
      ${CMAKE_BINARY_DIR}
      ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/src.cxx
      COMPILE_DEFINITIONS ${CMAKE_REQUIRED_DEFINITIONS}
      ${CHECK_CXX_SOURCE_COMPILES_ADD_LIBRARIES}
      CMAKE_FLAGS -DCOMPILE_DEFINITIONS:STRING=${MACRO_CHECK_FUNCTION_DEFINITIONS}
      "${CHECK_CXX_SOURCE_COMPILES_ADD_INCLUDES}"
      OUTPUT_VARIABLE OUTPUT)

    foreach(_regex ${_FAIL_REGEX})
      if("${OUTPUT}" MATCHES "${_regex}")
        set(${VAR} 0)
      endif()
    endforeach()

    if(${VAR})
      set(${VAR} 1 CACHE INTERNAL "Test ${VAR}")
      if(NOT CMAKE_REQUIRED_QUIET)
        message(STATUS "Performing Test ${VAR} - Success")
      endif()
      file(APPEND ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeOutput.log
        "Performing C++ SOURCE FILE Test ${VAR} succeeded with the following output:\n"
        "${OUTPUT}\n"
        "Source file was:\n${SOURCE}\n")
    else()
      if(NOT CMAKE_REQUIRED_QUIET)
        message(STATUS "Performing Test ${VAR} - Failed")
      endif()
      set(${VAR} "" CACHE INTERNAL "Test ${VAR}")
      file(APPEND ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeError.log
        "Performing C++ SOURCE FILE Test ${VAR} failed with the following output:\n"
        "${OUTPUT}\n"
        "Source file was:\n${SOURCE}\n")
    endif()
  endif()
endmacro()

如果我更新模块中的try_compile 命令如下，我可以使用armcc 检查C++ 功能而不会出现任何错误。

try_compile(${VAR}
  ${CMAKE_BINARY_DIR}
  ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/src.cxx
  COMPILE_DEFINITIONS ${CMAKE_REQUIRED_DEFINITIONS}
  ${CHECK_CXX_SOURCE_COMPILES_ADD_LIBRARIES}
  "${CHECK_CXX_SOURCE_COMPILES_ADD_INCLUDES}"
  OUTPUT_VARIABLE OUTPUT)

【讨论】：