如何在 Perl 函数中获取多个参数？

Question

在我的代码中，我一直在使用从函数调用中提取参数的相当原始的方法，如下所示：

sub addSix ($$$$$$) {
    my ($a, $b, $c, $d, $e, $f) = (shift, shift, shift, shift, shift, shift);
    return $a + $b + $c + $d + $e + $f;
}

print addSix (1, 2, 3, 4, 5, 6) . "\n";

（忘记原始代码，显着位是多个shift 调用）。

现在这对我来说似乎相当混乱，虽然 Perl 可能有类似的东西：

my ($a, $b, $c, $d, $e, $f) = shift (6);

或类似的东西。

但我找不到类似的东西。我知道我可以为此使用数组，但我认为我仍然必须将数组解压缩为单独的标量。这对于上面的示例情况来说并不算太糟糕，其中六个参数相似，但我更感兴趣的是它们并不真正适合作为数组的情况。

如何在提取参数时避免陷入shift 关键字的泥潭？

Answer 1

您只需输入：

my ($a, $b, $c, $d, $e, $f) = (@_);

如果您没有该原型，并且如果调用该 sub 时使用了六个以上的参数，则第六个之后的参数只是“不匹配”，$f 将设置为第六个参数。

如果你想捕捉第六个之后的所有参数，你可以这样做。

my ($a, $b, $c, $d, $e, $f, @others) = (@_);

如果您的标量列表比右侧的列表长，则最后一个元素将为undef。

Answer 2

除非有真正需要，否则强烈建议不要使用原型。

与 Perl 一样，有不止一种方法可以做到这一点。

这是保证只添加传递的前六个参数的一种方法：

use List::Util 'sum';

sub addSix { sum @_[0..5] }

或者，如果您喜欢自记录代码：

sub addSix {

    my @firstSix = @_[0..5];  # Copy first six elements of @_
    return sum @firstSix;
}

Answer 3

我意识到这是一个旧线程，但它让我想到了一种更好的方法来转移多个值。这只是一点点乐趣......主要出于教育目的发布此内容。

当然，如果您想保留@_，($x, $y) = @_ 很好，但也许您出于某种原因想改变您的论点？或许您想要由@_ 中剩余参数的数量确定的任何其他子例程功能。

我能想到的最简洁的单行方式就是使用一张简单的地图

sub shiftySub {
    map { $_ = shift } my ($v, $w, $x, $y);
    # @_ now has up to 4 items removed
    if (@_) { ... } # do stuff if arguments remain
}

• 如果提供了 4 个参数，@_ 现在在子作用域中为空。
• 如果提供了 5 个参数，@_ 在子范围内剩余 1 个项目。
• 如果提供3个参数，@_为空，$y为undef 范围。

---

关于paxdiablo 的理论shift(6) 运算符，我们可以创建自己的函数来执行此操作...

sub shifter (\@;$) {
    my ( $array, $n ) = ( @_, 1 );
    splice( @$array, 0, $n );
}

该函数通过强制传递引用原型（您应该使用原型的非常有限的原因之一）来确保数组在调用范围内移动。然后你就这样简单地使用它......

my @items = ('one', 'two', 'three', 'four');
my ($x, $y) = shifter(@items, 2);
# or as a replacement for shift
my $z = shifter(@items)
# @items has 1 item remaining in this scope!

当然，您也可以在其他潜艇中使用这个shifter 函数。像这样的函数的主要缺点是您必须跟踪运算符两侧的赋值数。

希望my $post = 'informative' || 'interesting';