跨行拆分单行

Question

给定一个Promotion 表，其中包含以下行和数据：

PromotionId    Codes
1              a,b
2              c
3              d,e,f

我如何编写一个查询来返回它：

PromotionId    Codes
1              a
1              b
2              c
3              d
3              e
3              f

基本上我想将代码字符串拆分为多行。

Answer 1

您可以使用Split 表值函数，例如：

CREATE FUNCTION [dbo].[Split]
(
    @ItemList NVARCHAR(MAX), 
    @delimiter CHAR(1)
)
RETURNS @IDTable TABLE (Item VARCHAR(50))  
AS      

BEGIN    
    DECLARE @tempItemList NVARCHAR(MAX)
    SET @tempItemList = @ItemList

    DECLARE @i INT    
    DECLARE @Item NVARCHAR(4000)

    SET @tempItemList = REPLACE (@tempItemList, ' ', '')
    SET @i = CHARINDEX(@delimiter, @tempItemList)

    WHILE (LEN(@tempItemList) > 0)
    BEGIN
        IF @i = 0
            SET @Item = @tempItemList
        ELSE
            SET @Item = LEFT(@tempItemList, @i - 1)
        INSERT INTO @IDTable(Item) VALUES(@Item)
        IF @i = 0
            SET @tempItemList = ''
        ELSE
            SET @tempItemList = RIGHT(@tempItemList, LEN(@tempItemList) - @i)
        SET @i = CHARINDEX(@delimiter, @tempItemList)
    END 
    RETURN
END  

那么你可以使用CROSS APPLY加入它：

SELECT PromotionId, CodeList.Item AS Codes
FROM Promotion p
    CROSS APPLY dbo.Split(Codes, ',') CodeList

编辑：以下是您的数据：http://sqlfiddle.com/#!3/85f8b/1/0

结果：

PROMOTIONID    CODES
  1             a
  1             b
  2             c
  3             d
  3             e
  3             f

Answer 2

如何将 SQL 与 XML 结合使用，如下所示：

declare @X xml

SET @X= (SELECT CONVERT(xml,'<s id="'+cast(PromotionId as varchar)+'">' + REPLACE(Codes,',','</s><s id="'+cast(PromotionId as varchar)+'">') + '</s>') FROM t1
FOR XML RAW)

SELECT c.value('(@id)[1]','int') as PromotionId, c.value('.','varchar(50)') as Code
FROM @X.nodes('/row/s') T(c)

会更高效更快

SQLFiddle Demo

Answer 3

我相信在 T-SQL 中拆分/联系事物的最快方法是使用 XML。这是我使用的解决方案：

;WITH CTE(PromotionID,Codes)
AS
(
    SELECT  PromotionID
           ,CAST(N'<r><![CDATA[' + REPLACE(Codes, ',', ']]></r><r><![CDATA[') + ']]></r>' AS XML) AS Codes
    FROM @SourceTable
)
SELECT  PromotionID
       ,Code
FROM CTE
CROSS APPLY (SELECT DISTINCT RTRIM(LTRIM(Tbl.Col.value('.', 'nvarchar(250)'))) AS Code FROM Codes.nodes('//r') Tbl(Col)) AS List

我已使用公用表表达式将代码转换为 XML。然后我只使用一种常用方法将 XML 拆分为单个元素。这是完整的工作示例：

SET NOCOUNT ON
GO

DECLARE @SourceTable TABLE
(
    PromotionID INT,
    Codes NVARCHAR(20)
)

INSERT INTO @SourceTable (PromotionID,Codes)
VALUES   (1,'a,b')
        ,(2,'c')
        ,(3,'d,e,f')

;WITH CTE(PromotionID,Codes)
AS
(
    SELECT  PromotionID
           ,CAST(N'<r><![CDATA[' + REPLACE(Codes, ',', ']]></r><r><![CDATA[') + ']]></r>' AS XML) AS Codes
    FROM @SourceTable
)
SELECT  PromotionID
       ,Code
FROM CTE
CROSS APPLY (SELECT DISTINCT RTRIM(LTRIM(Tbl.Col.value('.', 'nvarchar(250)'))) AS Code FROM Codes.nodes('//r') Tbl(Col)) AS List


SET NOCOUNT OFF
GO