Excel VBA 在第二个空格后拆分

Question

我正在尝试拆分我的列，以便名称

詹姆斯·约翰·多伊

只出来

詹姆斯·约翰

使用下面的公式，但它只留下名字，我希望它在第二次出现“空格”时拆分。

Sub Split1()
Dim r As Range

For Each r In Range("A2:A" & Cells(Rows.count, "A").End(xlUp).Row).Cells.SpecialCells(xlCellTypeConstants)
    r.Value = Split(r.Value, " ")(0)
    
Next r

谁能帮帮我？

谢谢

Answer 1

您可以尝试使用left & find 来获取字符串值直到第二个空格，而不是split 函数

代码修改：

Dim r As Range
Dim s As String, newText As String
Dim Length As Long

For Each r In Range("A2:A" & Cells(Rows.Count, "A").End(xlUp).Row).Cells.SpecialCells(xlCellTypeConstants)
    s = r.Value
    Length = Application.WorksheetFunction.Find(" ", s, Application.WorksheetFunction.Find(" ", s) + 1)
    
    r.Value = Left(s, Length)
Next r

样本输出：

Answer 2

有几种方法可以将三个单词的短语变成前两个单词。

让我们从您的Split() 方法开始。 该函数返回一个数组。您尝试访问索引的特定方法只会返回一个单词。

你可以放入一个数组，然后组合数组元素：

For Each r In Range(...)

    Dim retVal() As String
    retVal = Split(r.Value)
    r.Value = retVal(0) & " " & retVal(1)

Next r

您可以使用Replace() 删除最后一个单词：

For Each r In Range(...)

    r.Value = Replace(r.Value, Split(r.Value)(2), "")

Next

或者你甚至可以使用正则表达式：

With CreateObject("VBScript.RegExp")

    .Pattern = "\s[^\s]+$"
    For Each r in Range(...)
        r.Value = .Replace(r.Value, "")
    Next
    
End With

在正则表达式中，\s 表示单个空格字符，[^...] 括号表示“不包括”，我们在括号内放置了一个\s，这样可以匹配任何 非空格字符，后跟+表示1次或多次，最后$表示字符串结束。本质上，您想要匹配位于字符串$ 末尾的单词[^\s]+，前面有一个空格\s，并通过.Replace() 方法将其删除。实际上，您也可以简单地使用模式\s\S+$，它本质上是相同的（\S 表示任何大写的非空格字符）。

Answer 3

提取拆分数组的第一个和第三个标记的进一步方法

这种方法得益于Application.Index 的高级可能性，允许指示任何新的行或列顺序；想要的列在此处由最后一个基于 1 的（列）参数 Array(1, 3) 反映：

Function GetFirstLast(s As String) As String
    GetFirstLast = Join(Application.Index(Split(s), 0, Array(1, 3)))
End Function

调用示例：

Debug.Print GetFirstLast("James John Doe")

导致

James Doe 在 VB 编辑器的即时窗口中。