如何在 perl 6 中“展平”列表列表？

Question

假设我想要 a、b 和 c 中 2 个字母的所有排列。

我能做到：

my @perm = <a b c>.combinations(2)».permutations;
say @perm;
# [((a b) (b a)) ((a c) (c a)) ((b c) (c b))]

这很接近，但不完全是我需要的。 我如何“展平”这个以便我得到：

# [(a b) (b a) (a c) (c a) (b c) (c b)]

?

Answer 1

另见"a better way to accomplish what I (OP) wanted"。

另见"Some possible solutions" answer to "How can I completely flatten a Raku list (of lists (of lists) … )" question。

添加下标

my \perm = <a b c>.combinations(2)».permutations;
say perm;       # (((a b) (b a)) ((a c) (c a)) ((b c) (c b)))
say perm[*];    # (((a b) (b a)) ((a c) (c a)) ((b c) (c b)))
say perm[*;*];  # ((a b) (b a) (a c) (c a) (b c) (c b))
say perm[*;*;*] # (a b b a a c c a b c c b)

注意事项

我使用了一个非印记变量，因为我认为对于那些不了解 Raku 的人来说，它更清楚发生了什么。

我没有将下标附加到原始表达式，但我可以：

my \perm = <a b c>.combinations(2)».permutations[*;*];
say perm;       # ((a b) (b a) (a c) (c a) (b c) (c b))

Answer 2

最终，您构建列表的方式一开始就错误。您可以像这样将您的排列slip 放入外部列表中。

<a b c>.combinations(2).map(|*.permutations);

产生以下列表

((a b) (b a) (a c) (c a) (b c) (c b)) 

根据Bench 模块，这比做快了大约 300%

<a b c>.combinations(2).map(*.permutations)[*;*]

Answer 3

my @perm = <a b c>.combinations(2)».permutations;
dd [ @perm.map(*.Slip) ]
# OUTPUT«[("a", "b"), ("b", "a"), ("a", "c"), ("c", "a"), ("b", "c"), ("c", "b")]␤»

但是，您最好在稍后在程序中使用 LoL 时对其进行解构。长列表上的地图可能需要很长时间。

Answer 4

根据需要插入slips，例如通过

<a b c>.combinations(2).map(*.permutations.Slip).Array

或

[ slip .permutations for <a b c>.combinations(2) ]

如果您可以使用Seq，则无需在第一个示例中调用.Array，如果不需要可变性，则可以调用.list 或.cache（由PositionalBindFailover 提供）替换.

在第二个示例中，可以使用前缀 | 运算符代替 slip 子运算符。