Gnuplot：忽略数据文件中第一行的最短方法

Question

我有一个由另一个 3rd 方应用程序创建的 .csv 数据文件，应该使用 gnuplot 绘制。 假设该文件具有以下格式：

1;2;3;4;5;6 <-- This is the header line that should be ignored (with values 1;2;...;N)
1;1;2;1;1;1
2;3;3;3;5;6
3;4;1;1;1;4

第一列是 x 轴，以下列各应绘制为自己的线图（是的，我知道，一个图中的线图过多可能看起来很糟糕，但只是为了了解一下）。这里是一个 MCVE：

set terminal png size 1000,500    
set datafile separator ";" # CSV file is seperated with ;
plot \
  'C://tmp/test.csv' using 1:2 with lines title "A",\
  'C://tmp/test.csv' using 1:3 with lines title "B",\
  'C://tmp/test.csv' using 1:4 with lines title "C",\
  'C://tmp/test.csv' using 1:5 with lines title "D",\
  'C://tmp/test.csv' using 1:6 with lines title "E"

问题是，这也将第一行绘制为数据。

我知道可以通过以# 开头来忽略数据文件中的任何行，例如#1;2;3;4;5;6，但我不想编辑该文件，因为它也被其他工具使用。

另一种方法是使用plot <filename> every ::1 忽略第一行，这意味着我必须在上述脚本中包含every ::1 5 次，如in this link 所述。如下所示：

set terminal png size 1000,500    
set datafile separator ";" # CSV file is seperated with ;
plot \
  'C://tmp/test.csv' every ::1 using 1:2 with lines title "A",\
  'C://tmp/test.csv' every ::1 using 1:3 with lines title "B",\
  'C://tmp/test.csv' every ::1 using 1:4 with lines title "C",\
  'C://tmp/test.csv' every ::1 using 1:5 with lines title "D",\
  'C://tmp/test.csv' every ::1 using 1:6 with lines title "E"

为每个情节定义every ::1真的是唯一的方法吗？是否有一些更短 - 更可取的单行 - 忽略第一（n）行的方法？某种方式来定义every ::1“全局”或类似（伪代码）set datafile ignorefirstnlines 1？

Answer 1

Gnuplot 可以从第一行读取列名，但您仍然可以正常指定列名。因此，这实际上跳过了第一行。

发出命令

set key autotitle columnhead

这告诉 gnuplot 第一行不是数据，而是用于键的列名。您仍然可以像以前一样使用 unset key 或 plot datafile title sometitle，而 gnuplot 不会使用这些数据。

假设我的文件看起来像

1 2
4 5
7 8

我可以只发出set key autotitle columnhead 后跟unset key（如果我真的不想要密钥），它会跳过第一行。

---

或者，我可以通过外部程序管道我的数据。例如，使用 awk（适用于包括 Windows 在内的大多数操作系统），我可以这样做

plot "< awk '(NR>2){print;}' datafile"

跳过前 2 行（使用 Windows，我必须这样做 '< awk "(NR>2){print;}" datafile'）。如果我不想继续输入，我可以将其存储在字符串中

skipfile = "\"< awk '(NR>2){print;}' datafile\""

并将其用作宏（对于 Windows，使用 skipfile = '"< awk \"(NR>2){print;}\" datafile"'）。例如，要使用线条绘制数据文件，我可能会这样做

plot @skipfile with lines

@skipfile 只是告诉 gnuplot 处理该命令，就像我刚刚在此处键入 skipfile 的内容一样。