VBNET：如何对对象列表进行分组，并将一些属性组合为数组？

Question

我有一个包含不同值的 SQL 数据库：名称、尺寸、重量、价格和材料。

每个产品可以有多种材料。 如下例：产品 1 有 3 种材料，产品 2 有 2 种材料。

Name	Dimension	Weight	Price	Material
Product 1	340	3.0	23.55	Steel
Product 1	340	3.0	23.55	Brass
Product 1	340	3.0	23.55	Copper
Product 2	214	2.3	13.25	Steel
Product 2	214	2.3	13.25	Gold

我现在想要实现的事情，是按名称对这些数据进行分组，并将所有材料组合成一个材料数组。

注意：为每种材料添加了一条新的 sql 记录，但名称、尺寸、重量和价格在这些行中保持不变。 （只有材料变化）

    Public Class Product
      Public Property name As String
      Public Property dimension As Integer
      Public Property weight As Double
      Public Property price As Double
      Public Property materials() As String
    End Class

到目前为止我所尝试的：

    Using conn As SqlConnection = New SqlConnection("Data source 
       =db;Initial Catalog=ProductData;Integrated 
       security=True")
       Dim cmd As New SqlCommand("select * from dbo.Product_data_db", 
       conn)
       Dim adapter As New SqlDataAdapter(cmd)
       adapter.Fill(table)
    End Using

Dim products As List(Of Product) = table.AsEnumerable().
Select(Function(x) New Product(x)).
GroupBy(Function(x) x.name).
Select(Function(y) New Product With 
{.name = y.Key, .materials = y.Select(Function(x) x.materials()}).ToList

预期结果：

包含 2 个项目的列表（产品）：

第 1 项：

• name = "产品 1"
• 尺寸 = 340
• 重量 = 3.0
• 价格 = 23.55
• 包含材料的字符串数组 = 钢、黄铜、铜

第 2 项：

• name = "产品 2"
• 尺寸 = 214
• 重量 = 2.3
• 价格 = 13.25
• 包含材料的字符串数组 = 钢、金

Answer 1

所以实际上您正在使用 ADO.NET 将整个表加载到内存中（DataTable）。如果它不会增长也没关系，但它不是一种可扩展的方法。不过……

您可以使用GroupBy，例如在这个包含产品字段的 ValueTuple 上：

Dim products As List(Of Product) = table.AsEnumerable().
    GroupBy(Function(row) (Name:=row.Field(Of String)("Name"), Dimension:=row.Field(Of Int32)("Dimension"), Weight:=row.Field(Of Decimal)("Weight"), Price:=row.Field(Of Decimal)("Price"))).
    Select(Function(g) New Product With
    {
        .name = g.Key.Name,
        .dimension = g.Key.Dimension,
        .weight = g.Key.Weight,
        .price = g.Key.Price,
        .materials = g.Select(Function(row) row.Field(Of String)("Material")).ToArray()
    }).
    ToList()