PIVOT SQL 数据和填空

Question

我正在尝试转换这些数据：

ItemID  MonthAsInt  Month     Year  InvType     Quantity
4643    4           April     2011  Shipment    10
4643    5           May       2011  Shipment    10
4643    7           July      2011  Shipment    10
4643    8           August    2011  Destroy     10
4643    11          November  2011  Shipment    25
4643    12          December  2011  Picking     1

进入这个（基本上是 12 个月的快照）：

              February    March    April     May    June    July    August    ...

Shipment      0           0        10        10     0       10      0
Picking       0           0        0         0      0       0       0
Destroy       ...

我搞砸了PIVIOT 方法，但运气不佳。此时，我所拥有的只是GETDATE() 和GETDATE() - 12 months 之间需要的日期列表（通过以下查询检索）：

DECLARE @BeginDate DATETIME
DECLARE @EndDate DATETIME

SET @BeginDate = GETDATE();
SET @EndDate = DATEADD(MONTH, -12, GETDATE());

WITH CTE_DatesTable
AS
(
    SELECT @EndDate AS [Date]

    UNION ALL

    SELECT  DATEADD(dd, 1, [date])
    FROM    CTE_DatesTable
    WHERE   DATEADD(dd, 1, [date]) <= @BeginDate
)

SELECT DISTINCT DATENAME(MONTH, [date]) + ' ' 
        + CAST(YEAR([date]) AS VARCHAR(4)) AS MonthYear,
                YEAR([date]) AS YearAsInt,
                MONTH([Date]) AS MonthAsInt
FROM            CTE_DatesTable
ORDER BY        YEAR([date]), MONTH([Date])
OPTION          (MAXRECURSION 0)

查看实际查询here。

我想要完成的事情可能吗？我是否朝着正确的方向前进？任何帮助将不胜感激！

Answer 1

如果您需要动态枢轴：see here

否则

这就是你做它的方式。当然，PIVOT 要求您事先知道您的数据会是什么样子。如果您需要动态透视，那么人们已经编写了很多动态交叉表/透视查询/sps。

DECLARE @BeginDate DATETIME
DECLARE @EndDate DATETIME

SET @BeginDate = GETDATE();
SET @EndDate = DATEADD(MONTH, -12, GETDATE());

WITH CTE_DatesTable
AS
(
    SELECT @EndDate AS [Date]

    UNION ALL

    SELECT  DATEADD(dd, 1, [date])
    FROM    CTE_DatesTable
    WHERE   DATEADD(dd, 1, [date]) <= @BeginDate
)

    SELECT DISTINCT DATENAME(MONTH, [date]) + ' ' + CAST(YEAR([date]) AS VARCHAR(4)) AS MonthYear,
                    YEAR([date]) AS YearAsInt,
                    MONTH([Date]) AS MonthAsInt,
                    case when month([date]) < 5 then 'Shipment' else 'Picking' end InvType,
                    floor(10 * RAND() * month([date])) Quantity
    into #orig
    FROM            CTE_DatesTable
    ORDER BY        YEAR([date]), MONTH([Date])
    OPTION          (MAXRECURSION 0)

update #orig 
set Quantity = null
where MonthYear = 'February 2011'

select * from #orig

select *
from
(
    select isnull(Quantity, 0) Quantity, MonthYear from #orig
) SourceTbl
PIVOT
(
    sum(Quantity)
    for MonthYear in ([February 2011], [March 2011])
) PivotTbl

drop table #orig

结果：

February 2011   March 2011
0                   29

Answer 2

您可以在没有枢轴的情况下执行此操作（我也觉得令人生畏的语法）。由于您事先不知道列的实际布局，因此我认为使用动态 SQL 最简单。给定下表/示例数据：

USE tempdb;
GO

CREATE TABLE dbo.foo
(
    ItemID INT, 
    MonthAsInt INT, 
    [Month] VARCHAR(12), 
    [Year] INT, 
    InvType VARCHAR(12), 
    Quantity INT
);

INSERT dbo.foo SELECT 4643,4 ,'April   ',2011,'Shipment',10
UNION ALL SELECT 4643,5 ,'May     ',2011,'Shipment',10
UNION ALL SELECT 4643,7 ,'July    ',2011,'Shipment',10
UNION ALL SELECT 4643,8 ,'August  ',2011,'Destroy ',10
UNION ALL SELECT 4643,11,'November',2011,'Shipment',25
UNION ALL SELECT 4643,12,'December',2011,'Picking ',1;

您可以使用更简单的 CTE 生成月份列表，并在此基础上构建动态 SQL 语句：

DECLARE @sql NVARCHAR(MAX) = N'';

;WITH n AS 
(
    SELECT TOP (12) d = DATEADD
    (
        MONTH, 
        -(ROW_NUMBER() OVER (ORDER BY [object_id]) - 1), 
        GETDATE()
    )
    FROM sys.objects
    ORDER BY d DESC
)
SELECT @sql = @sql + N',' + CHAR(13) + CHAR(10) + DATENAME(MONTH, d) 
    + ' = SUM(CASE WHEN [Year] = ' + CONVERT(VARCHAR(4), DATEPART(YEAR, d))
    + ' AND MonthAsInt = ' + CONVERT(VARCHAR(2), DATEPART(MONTH, d)) 
    + ' THEN Quantity ELSE 0 END)'
FROM n
ORDER BY d;

SELECT @sql = N'SELECT InvType' + @sql + '
    FROM dbo.foo
    GROUP BY InvType';

PRINT @sql;
-- EXEC sp_executesql @sql;

我把PRINT 放在那里，这样你就可以在运行它之前对其进行测试。我不确定您需要 12 个月还是 13 个月，如果您想要 13 个月，您可以将 TOP (12) 更改为 TOP (13)，或者如果您不希望包含当前月份，请删除 -1。