如何从我的 ACCESS 表中删除所有 NA 值？

Question

是否存在类似以下的查询：

UPDATE FieldName FROM TableName WHERE FieldName IN('NA') SET FieldName = NULL

事实上FieldName 可以是任何字段？

举例

Field1	Field2	Field3	Field4	....	Field100
013475	486466	486655	156861	....	15351312
013475	NA	486655	156861	....	15351312
013475	486466	NA	156861	....	NA
013475	486466	486655	NA	....	NA

执行查询后我应该有：

Field1	Field2	Field3	Field4	....	Field100
013475	486466	486655	156861	....	15351312
013475		486655	156861	....	15351312
013475	486466		156861	....
013475	486466	486655		....

请注意，我正在处理访问权限。

Answer 1

必须明确引用要更新的每个字段。

考虑具有 2 个字段的示例：

UPDATE tablename SET Field2 = IIf(Field2 = "NA", Null, Field2),
                     Field3 = IIf(Field3 = "NA", Null, Field3)

或者，构建 VBA 过程以对记录集执行编辑或在循环中运行重复的 UPDATE 操作语句。

否则，打开表并在整个表上运行一次性查找/替换。

Answer 2

没有。 SQL 中的字段名和表名不能是动态的。

将 DAO 用于此类任务：

Public Function CleanNa()

    Dim Records As DAO.Recordset
    Dim Field   As DAO.Field
    
    Dim Sql     As String
    
    Sql = "Select * From Tablename"
    
    Set Records = CurrentDb.OpenRecordset(Sql)
    
    Records.MoveFirst
    While Not Records.EOF
        For Each Field In Records.Fields
            If Field.Value = "NA" Then
                Records.Edit
                Field.Value = Null
                Records.Update
            End If
        Next
        Records.MoveNext
    Wend
    Records.Close
    
End Function

Answer 3

您可以做的一件事是使用一些 VBA 循环字段并运行一组更新语句。比如：

Sub sUpdateData()
    Dim db As DAO.Database
    Dim tdf As DAO.TableDef
    Dim fld As DAO.Field
    Dim strSQL As String
    Set db = CurrentDb
    Set tdf = db.TableDefs("TableName")
    For Each fld In tdf.Fields
        strSQL = "UPDATE TableName SET [" & fld.Name & "]=NULL WHERE [" & fld.Name & "]='NA';"
        db.Execute strSQL
    Next fld
    Set tdf = Nothing
    Set db = Nothing
End Sub