删除字符串数组中的重复值？答案

【问题标题】：Remove duplicate values in string array?删除字符串数组中的重复值？
【发布时间】：2022-09-29 01:46:08
【问题描述】：

有一个字符串数组，其中包含多个字符串，其中多个字符串彼此相似。要求是删除数组中的重复项。

输入：

[\"Anne\", \"Jane\", \"John\", \"Jane\", \"Ivan\", \"Peter\", \"Anne\"]

输出：

[\"Anne\",\"Jane\",\"John\",\"Ivan\",\"Peter\"]

似乎没有 langlib 函数可以直接实现这一点。如何使用 Ballerina 删除数组中的重复字符串？

标签： ballerina

【解决方案1】：

这是从字符串数组中删除重复项的两种方法。

方法一：使用lang.array的indexOf方法

方法二: 使用lang.map的keys方法

示例代码如下。

import ballerina/io;

// Method 1
function getUniqueValues(string[] names) returns string[] {
    string[] uniqueNames = [];
    foreach string name in names {
        if uniqueNames.indexOf(name) is () {
            uniqueNames.push(name);
        }
    }
    return uniqueNames;
}

//Method 2
function getUniqueValuesUsingMap(string[] names) returns string[] {
    map<()> mapNames = {};
    foreach var name in names {
        mapNames[name] = ();
    }
    return mapNames.keys();
}

public function main() {
    string[] duplicatedStrings = ["Anne", "Jane", "John", "Jane", "Ivan", "Peter", "Anne"];

    //Using Method 1
    io:println(getUniqueValues(duplicatedStrings));

    //Using Method 2
    io:println(getUniqueValuesUsingMap(duplicatedStrings));

}

【讨论】：