如何翻转谷歌表格中的字符串答案

【问题标题】：How to Flip a string in google sheets如何翻转谷歌表格中的字符串
【发布时间】：2022-09-27 15:12:23
【问题描述】：

我在左侧有这个谷歌表格输入列，我想翻转字符串，如输出列中所示。

Input   Output
--------------
bats    stab
live    evil
meet    teem
part    trap
stop    pots

标签： google-sheets lambda sequence textjoin byrow

【解决方案1】：

使用此公式，只需将 A2:A 范围替换为您的。

=ArrayFormula(IF(A2:A="","",
              BYROW(A2:A, LAMBDA(range, 
              TEXTJOIN("",FALSE,MID(range,SEQUENCE(LEN(range),1,LEN(range),-1),1))))))

使用的公式帮助
ARRAYFORMULA - IF - BYROW - LAMBDA - TEXTJOIN - MID - SEQUENCE - LEN

【讨论】：

【解决方案2】：

尝试：

=IFERROR(BYROW(A1:A, LAMBDA(x, JOIN(, 
 INDEX(MID(x, LEN(x)-SEQUENCE(1, LEN(x))+1, 1))))))

或者：

=IFERROR(BYROW(A1:A, LAMBDA(x, JOIN(, INDEX(REGEXREPLACE(""&x, 
 REPT("(.)", LEN(x)), "$"&LEN(x)-SEQUENCE(1, LEN(x), )))))))

【讨论】：

先放第二个，之前没想到。

【解决方案3】：

使用 regex 分隔符将字符串拆分为其字符，然后使用 REDUCE 将字符串拆分为 current&accumulator（此处发生反转）：

=REDUCE(,SPLIT(REGEXREPLACE(A2,,"?"),"?"),LAMBDA(a,c,c&a))

对于数组，使用BYROW：

=BYROW(A2:INDEX(A2:A,COUNTA(A2:A)),LAMBDA(str,REDUCE(,SPLIT(REGEXREPLACE(str,,"?"),"?"),LAMBDA(a,c,c&a))))

【讨论】：

?????????

【解决方案4】：

尝试：

=IFERROR(BYROW(A1:A, LAMBDA(x, JOIN(, 
 INDEX(MID(x, LEN(x)-SEQUENCE(1, LEN(x))+1, 1))))))

【讨论】：