如何自动过滤具有来自特定范围的值的列

Question

大家好，我希望你能帮我解决这个问题，因为我刚开始学习 VBA :)

我需要使用来自另一个工作表中某个范围的值自动过滤 Excel 工作表的一列。有点复杂，这个范围是动态的，可能包括代码应该采用并用于自动过滤的不同数字行（每个单元格包含不同的文本）

这是我写的

Sub Filtrapp()
 
Worksheets("Applicazioni").Activate
Range("A8:C1000").AutoFilter 1, Worksheets("RecordTabella").Range("C2:C5").Value

End Sub 

这里的问题是过滤器只取最后一个单元格“C5”的值，而不是 C2、3、4 的值 我也试着让它动态，但每次都给我错误，希望有人能帮忙

提前致谢

Answer 1

使用数组作为条件过滤范围

Sub Filtrapp()
    
    Dim wb As Workbook: Set wb = ThisWorkbook ' workbook containing this code
    
    Dim sws As Worksheet: Set sws = wb.Worksheets("RecordTabella")
    
    Dim srg As Range
    Dim srCount As Long
    
    With sws.Range("C2")
        Dim lCell As Range: Set lCell = .Resize(sws.Rows.Count - .Row + 1) _
            .Find("*", , xlFormulas, , , xlPrevious)
        If lCell Is Nothing Then Exit Sub ' empty criteria column range
        srCount = lCell.Row - .Row + 1
        Set srg = .Resize(srCount)
    End With
    
    Dim Data As Variant ' 2D one-based
    If srCount = 1 Then ' one cell (row)
        ReDim Data(1 To 1, 1 To 1): Data(1, 1) = srg.Value
    Else ' multiple cells (rows)
        Data = srg.Value
    End If
    
    Dim Arr() As String: ReDim Arr(1 To srCount) ' 1D one-based
    
    Dim r As Long
    
    For r = 1 To srCount
        Arr(r) = Data(r, 1)
    Next r
    
    Dim dws As Worksheet: Set dws = wb.Worksheets("Applicazioni")
    If dws.FilterMode Then dws.ShowAllData
    
    Dim drg As Range: Set drg = dws.Range("A8:C1000")
    
    drg.AutoFilter 1, Arr, xlFilterValues
    
End Sub

Answer 2

你的意思是这样的吗？

这将按 >10 和 的值进行过滤

Worksheets("Applicazioni").Range("C1").AutoFilter Field:=3, Criteria1:=">10", _
    Operator:=xlAnd, Criteria2:="<20"