在 SQL Server 中使用 IF 语句的表值函数

Question

我有一个学生表包含以下参数

[ID] [nvarchar](50) NOT NULL,
[Firsname] [nvarchar](50) NOT NULL,
[Lastname] [nvarchar](50) NOT NULL,
[Melicode] [nchar](10) NOT NULL,
[City] [nvarchar](50) NOT NULL,
[Province] [nvarchar](50) NOT NULL,
[Active] [int] NULL

我想编写一个名为 Show 的表值函数，它有一个参数作为数字。该函数将如下所示

• 如果 @number = 1 ，则返回 Student 表中的所有列
• 如果 @number = 2 ，则仅返回来自 Student 的 City
• 如果 @number = 3 ，则仅返回来自 Student 的省份

我编写了以下 T-SQL，但它仅适用于 (if (@number = 1))。当用户输入@number 为 2 或 3 时，该功能不起作用。谢谢你

 Create function Show(@number int)
RETURNS @result TABLE
(
    [ID] [nvarchar](50) NOT NULL,
    [Firsname] [nvarchar](50) NOT NULL,
    [Lastname] [nvarchar](50) NOT NULL,
    [Melicode] [nchar](10) NOT NULL,
    [City] [nvarchar](50) NOT NULL,
    [Province] [nvarchar](50) NOT NULL,
    [Active] [int] NULL
) 
AS
BEGIN

    IF  (@number = 1)
         INSERT INTO @result SELECT * from Student 

    IF (@number = 2)
         INSERT INTO @result (City) values ((SELECT City from Student))

     IF (@number = 3)
         INSERT INTO @result (Province) values ((SELECT Province from Student))

    RETURN -- @Players (variable only required for Scalar functions)

END

go
select *from dbo.show(1)

Answer 1

情况 2 和 3 的插入语句不正确。插入来自 select 语句的值时不需要 VALUES 关键字。

Answer 2

CREATE FUNCTION dbo.Show
(
    @number INT
)
RETURNS @result TABLE
(
    ID NVARCHAR(50),
    Firsname NVARCHAR(50),
    Lastname NVARCHAR(50),
    Melicode NCHAR(10),
    City NVARCHAR(50),
    Province NVARCHAR(50),
    Active INT
)
AS
BEGIN

    IF (@number = 1)
        INSERT INTO @result
        SELECT * FROM dbo.Student

    IF (@number = 2)
        INSERT INTO @result (City)
        SELECT City FROM dbo.Student

    IF (@number = 3)
        INSERT INTO @result (Province)
        SELECT Province FROM dbo.Student

    RETURN

END
GO

SELECT * FROM dbo.Show(2)

Answer 3

这行不通：

INSERT INTO @result (City) 
VALUES ((SELECT City from Student))

要么您将所有值作为标量 SQL 变量或文字 - 然后您可以使用

INSERT INTO @result (City) 
VALUES ('New York')

INSERT INTO @result (City) 
VALUES (@ChosenCity)

或您有一个 SELECT 语句来填充值 - 那么您需要以下语法：

INSERT INTO @result (City) 
    SELECT City 
    FROM Student

没有 VALUES 关键字。正如@GiorgiNakeuri 正确指出的那样 - 这将 fail 因为你的所有列都需要一个值（具有 NOT NULL 属性），所以这个插入不能成功 - 你需要提供 all NOT NULL 值（或为每一列定义一个默认值）

Answer 4

返回的表由结果表的声明方式决定。下面的查询有效（在某种意义上），但结果包括 NULLs 的所有列，这些列不是 @number 参数所针对的那些列：

CREATE TABLE dbo.z_Show (str1 VARCHAR(10), str2 VARCHAR(10), str3 VARCHAR(10))

INSERT z_show
SELECT 1, 1, 1 UNION ALL
SELECT 2, 2, 2 UNION ALL
SELECT 3, 3, 3

CREATE FUNCTION dbo.Show(@number int)
RETURNS @result TABLE
(
    --[ID] [nvarchar](50) NOT NULL,
    --[Firsname] [nvarchar](50) NOT NULL,
    --[Lastname] [nvarchar](50) NOT NULL,
    --[Melicode] [nchar](10) NOT NULL,
    --[City] [nvarchar](50) NOT NULL,
    --[Province] [nvarchar](50) NOT NULL,
    --[Active] [int] NULL
    str1 VARCHAR(10), str2 VARCHAR(10), str3 VARCHAR(10)
) 
AS
BEGIN
--for debugging|start
--DECLARE @number INT = 3
--DECLARE @result TABLE (str1 VARCHAR(10), str2 VARCHAR(10), str3 VARCHAR(10))
--for debugging|end

    IF  (@number = 1)
    BEGIN
           --PRINT ('IF (@number = 1)')
         INSERT INTO @result SELECT * from dbo.z_Show
    END

    IF (@number = 2)
    BEGIN
        --PRINT ('IF (@number = 2)')
         INSERT INTO @result (str2) SELECT str2 from dbo.z_Show
    END

     IF (@number = 3)
     BEGIN
           --PRINT ('IF (@number = 3)')
         INSERT INTO @result (str3) SELECT str3 from dbo.z_Show
     END

    RETURN -- @Players (variable only required for Scalar functions)
END

SELECT 'number 1 was passed', *
FROM dbo.show(1)

SELECT 'number 2 was passed', *
FROM dbo.show(2)

SELECT 'number 3 was passed', *
FROM dbo.show(3)

Answer 5

您提到@result 具有所有NOT NULL 列。如果您只想将城市插入该@result，它将把剩余的列作为Null，这就是发生错误的原因。您没有提到 @result 列是 NOT NULL 列，还有一个是。从INSERT 语句中删除VALUES 关键字，因为它正在插入Select 语句