如果有多个具有相同 proc 名称的源文件，如何从特定源文件调用 proc？

Question

我正在尝试编写一个包装 tcl，它获取多个 tcl 文件，并且这些 tcl 文件有一些在多个文件中具有相同名称的 proc。如何从特定文件显式调用 proc？

我搜索了堆栈溢出并遇到了 proc rename，但我想知道是否还有其他解决方案。也许更干净。

Answer 1

这有点棘手，但您可以继续使用从解释器来区分文件。

add.tcl

proc calculate {a b} {
        return [expr {$a+$b}]
}

sub.tcl

proc calculate {a b} {
        return [expr {$a-$b}]
}

file_src_manager.tcl

array set tclEngine {}
set files  {add.tcl sub.tcl}
foreach f $files {
  # Creating slave interpreter for each files.
  set tclEngine($f) [interp create]
  # Sourcing them in separate interpreter
  if {[catch {interp eval $tclEngine($f) "source $f"} issue]} {
    puts "Failed to source $f. Reason - $issue"
  }
}
# Calling add.tcl file's calculate method
puts [interp eval $tclEngine(add.tcl) "calculate 5 3"]
# Calling sub.tcl file's calculate method
puts [interp eval $tclEngine(sub.tcl) "calculate 5 3"]

输出

8
2

参考：interp

Answer 2

您可以在单独的命名空间中组织source'ed proc，例如，通过将脚本名称重新用作命名空间名称：

add.tcl

namespace eval ::[file tail [info script]] {
    proc calculate {a b} {
        return [expr {$a+$b}]
    }
    namespace export calculate
}

sub.tcl

namespace eval ::[file tail [info script]] {
    proc calculate {a b} {
        return [expr {$a-$b}]
    }
    namespace export calculate
}

然后，在您的主脚本中，您可以在不同的 proc 池之间来回切换，例如使用[namespace import]:

% source add.tcl
% source sub.tcl
% namespace import -force ::add.tcl::*
% calculate 5 3
8
% namespace import -force ::sub.tcl::*
% calculate 5 3
2

备注

• [info script] 返回当前来源的脚本文件（由source 命令在后台设置）。
• 确保[namespace export] 池化过程。否则，它们不会被导入。
• 在namespace import 上使用-force 标志将静默替换目标命名空间中的同名命令(procs)。
• 在从解释器上使用命名空间（如 Dinesh 所建议的那样）是一个后果问题和您的用例：过程是否需要共享某些状态（变量）或某些资源（通道）？是否应该限制 proc 仅使用其 source 上下文中的文件？等
• 您当然可以定义自己的 source 变体，以避免在每个 source'ed 脚本中出现样板。