TCL 中的 global 和 :: 有什么区别？

Question

我正在使用 EDA 软件。它要求我依赖全局变量。 假设我有一个 proc，我正在寻找一个全局变量 CCK_FOO。我有两个选择：

1. 在代码中使用global CCK_FOO。
2. 使用::CCK_FOO

就“管理级别”而言，它们看起来相同。这两种方法是否有“幕后”的利弊？我实际上更喜欢使用::，因为它可以最大限度地减少意外覆盖的机会。

Answer 1

在底层，使用::CCK_FOO在每次执行引擎使用它时都会经过解析的变量名路由，而global CCK_FOO允许引擎设置一个局部变量（带有一个局部变量表-LVT-槽）链接到全局变量。通过 LVT 访问要快得多，因为这只是 C 数组的索引（以及额外的指针取消引用，因为它是链接），而查找全局变量意味着进行哈希表查找（全局命名空间中有变量的哈希表执行）。 ::CCK_FOO 的实际内部解析为 :: 和 CCK_FOO 被缓存。

实际上，如果您只访问一个变量一次，使用::CCK_FOO 可能稍微快一点，但是一旦您使用它两次（更不用说更多），您就会获得更好的性能支付global CCK_FOO的额外费用并通过LVT索引访问它。

% proc style1 {} {
    set ::CCK_FOO abc
}
% proc style2 {} {
    global CCK_FOO
    set CCK_FOO abc
}
% time { style1 } 100000
0.52350635 microseconds per iteration
% time { style2 } 100000
0.5267007100000001 microseconds per iteration

请注意，上面的代码和下面的代码之间的时间无法比较，因为它们执行的其他工作量不同。相反，请查看 style1 和 style2 之间的时间差异。

% proc style1 {} {
    set ::CCK_FOO [string reverse $::CCK_FOO]
}
% proc style2 {} {
    global CCK_FOO
    set CCK_FOO [string reverse $CCK_FOO]
}
% time { style1 } 100000
0.9733970200000001 microseconds per iteration
% time { style2 } 100000
0.78782093 microseconds per iteration
# Calibration...
% time { string reverse abc } 100000
0.28694849 microseconds per iteration

如您所见，只有两次访问，我们通过使用global 获得了相当大的加速。