Oracle 将变量传递给函数

Question

我有一些使用硬编码日期的 SQL 代码。我的目标是删除硬编码的日期并用变量替换它们以使代码通用。

我的测试用例如下；

    CREATE OR REPLACE FUNCTION IsDate( p_str IN VARCHAR2, p_format IN VARCHAR2 ) RETURN NUMBER AS
   V_date DATE;
   BEGIN
      V_Date := TO_DATE( p_str, p_format );
       RETURN 1;
    EXCEPTION
      WHEN OTHERS THEN
         RETURN 0;
    END;

这很好用

   select IsDate(DATE '2021-07-31','YYYY-MM-DD') from dual;

这会导致错误（见下文）。有人可以解释这个问题以及如何解决它。 我正在测试实时 SQL。提前感谢所有回答的人。

   exec :my_date :=  DATE '2021-07-31';
   select IsDate( DATE my_date,'YYYY-MM-DD') from dual;

我遇到了错误

ORA-01008：并非所有变量都绑定 ORA-06512：在“SYS.DBMS_SQL”，第 1721 行
ORA-00936: 缺少表达式

Answer 1

自 12.2 以来有一个特殊功能 VALIDATE_CONVERSION 可以完全满足您的要求： VALIDATE_CONVERSION

例子：

SQL> select VALIDATE_CONVERSION('01-01-2000' as date,'dd-mm-yyyy') chk1 from dual;

      CHK1
----------
         1

SQL> select VALIDATE_CONVERSION('01-01-2000' as date,'yyyy-mm-dd') chk2 from dual;

      CHK2
----------
         0

livesql.oracle.com 也不支持exec 命令，这是一个 SQL*Plus 命令。所以如果你想用绑定变量测试你的函数，你可以使用简单的 PL/SQL 变量：

declare
    string_date varchar2(100);
    
    FUNCTION IsDate( p_str IN VARCHAR2, p_format IN VARCHAR2 ) RETURN NUMBER AS
        V_date DATE;
    BEGIN
        V_Date := TO_DATE( p_str, p_format );
        RETURN 1;
    EXCEPTION
        WHEN OTHERS THEN
            RETURN 0;
    END;
begin
    string_date:='31-12-2000';
    dbms_output.put_line(IsDate(string_date,'dd-mm-yyyy'));
end;
/

Answer 2

DATE 关键字需要文字，您不能使用字符串变量。

关于你的功能：

FUNCTION IsDate( p_str IN VARCHAR2, p_format IN VARCHAR2 ) RETURN NUMBER

它需要两个VARCHAR2，即字符串值。但是，当您运行 IsDate(DATE '2021-07-31','YYYY-MM-DD') 时，您会将 DATE 值传递给函数，而不是字符串。

检查DATE 值的格式是没有意义的，因为DATE 值本身没有格式，它被存储为内部二进制值。永远不要对已经是 DATE 的值使用 TO_DATE。函数TO_DATE 需要一个字符串，该字符串应转换为DATE。

当您选择DATE 时显示的内容由您当前的用户会话NLS_DATE_FORMAT 设置定义（默认情况下）。您可以更改默认输出格式，例如使用 ALTER SESSION SET NLS_DATE_FORMAT = 'DD.MM.YYYY'; 或使用 TO_CHAR() 函数显式设置。

当您调用函数IsDate(DATE '2021-07-31','YYYY-MM-DD') 时，Oracle 会隐式转换为字符串。即它运行

V_Date := TO_DATE( TO_CHAR(p_str, SYS_CONTEXT('USERENV', 'NLS_DATE_FORMAT')), p_format );

当你传递一个DATE 值时，你的函数实际上是这样的：

CREATE OR REPLACE FUNCTION IsDate( p_str IN VARCHAR2, p_format IN VARCHAR2 ) RETURN NUMBER AS
   ret NUMBER;
BEGIN
   SELECT COUNT(*)
   INTO ret
   FROM NLS_SESSION_PARAMETERS
   WHERE PARAMETER = 'NLS_DATE_FORMAT'
     AND VALUE = p_format;
   RETURN ret; 
   -- p_str is ignored completely
END;

注意，在 Oracle 18 中，TO_DATE 函数提供了 DEFAULT ... ON CONVERSION ERROR 子句，因此编写额外的函数可能有点过头了。