Perl数据结构遍历——引用跟随键

Question

结果：HASH(0x1948958) ARRAY(0x1978250) ./directory/filename 多行

想要的结果：[Key of first hash] [Key of second hash] ./directory/filename #(elements of array, currently working)

Catch：应该跨越到 N 级结构，因此我尝试使用 Data::Walk。

当我在结构中行走时，我真正想做的是引用正在使用的密钥。有点像 Data::Dumper 但制表符分隔而不是代码格式。我认为可能的解决方案（按优先顺序）是：

• 我忽略了一些对 Data::Walk 的调用。
• 我不知道这个任务的更好的模块。
• 我可以内联的快速代码 sn-p
• 我自己的模块/Data::Walk / Data::Dumper 的分支（皱眉）将添加此功能。

---

use strict;
use File::Basename;
use Data::Walk;

my $files;
while (<>) {
        chomp;
        #ls -l output in a file; referencing filename from it (8th column)
        my @line = split(/ /, $_, 8);
        #fileparse exported by File::Basename
        my ($name,$path) = fileparse($line[7]);
        open (my $fh, '<', $path . $name);
        my $sha = Digest::SHA->new('sha1');
        $sha->addfile($fh);
        #finding files by basename, then unique hash, then however many places it is stored.
        #question not why I don't use the hash as the first field.

        #basename    digest    path
        push(@{$files->{$name}->{$sha->hexdigest}}, $path . $name);
}

my @val;
sub walkit {
        $val[$Data::Walk::depth - 1] =  $_;
        if ($Data::Walk::depth == 3) {
                print join("\t", @val), "\n";
        }
}

&walk (\&walkit, %$files);

大师？

Answer 1

编辑：根据我的更好判断，我会尝试再次回答这个问题。

这是一种打印所需内容的简单方法。使用 Data::Walk 是不可行的，因为当你在散列中时没有关键上下文（你只是得到一个指向容器的指针。）

此函数适用于有些复杂的结构。当然，如果您将函数引用或一些奇怪的东西放在那里，它不会给出正确的输出。

use strict;
use warnings;

my $res;
sub walk {
    my ($item, $path) = @_;
    if (ref $item eq 'ARRAY') {
        foreach (@$item) {
            walk($_, $path);
        }
    } elsif (ref $item eq 'HASH') {
        foreach (keys %$item) {
            push @$path, $_;
            walk($item->{$_}, $path);
            pop @$path;
        }
    } else {
        print join('-', @$path, $item), "\n";
    }
}

my $struct = {
    a => {
            a1 => { a11 => [ 1, 2, 3 ] },
            a2 => { a22 => [5, 6, 7] }
    },
    b => { b1 => [ 99 ], },
    c => [ 100, 101, ],
    d => [ 101, { d2 => { d3 => [200, 210] }, }, ],
};

walk $struct;

Answer 2

for my $name (keys(%$files)) {
   for my $digest (keys(%{$files->{$name}})) {
      my @qfns = @{ $files->{$name}{$digest} };
      if (@qfns > 1) {
         say "For $name and $digest,";
         say "   $_" for @qfns;
      }
   }
}

（我假设您正在寻找重复项，因此当只有一个与名称摘要组合关联的路径时，我什么也不打印。如果您想打印所有内容，可以删除 if。）

其他一些清理工作：

use strict;
use warnings;
use 5.010;

use Digest::SHA    qw( );
use File::Basename qw( basename );

sub calc_digest {
   my ($qfn) = @_;
   open(my $fh, '<', $qfn) or die $!;
   my $sha = Digest::SHA->new('sha1');
   $sha->addfile($fh);
   return $sha->hexdigest();
}

my $files;
while (<>) {
   my $qfn = (split)[7];
   my $name = basename($path);
   my $digest = calc_digest($qfn);
   push @{ $files->{$name}{$digest} }, $qfn;
}

（“qfn”代表“限定文件名”，表示文件的路径，这不是$path 包含的内容。即使$line[7] 包含它，您仍在重复构建路径。）