如何将以下钩子移植到reasonml

Question

我有以下自定义钩子

function useConstant(fn) {
  const ref = React.useRef()

  if (!ref.current) {
    ref.current = fn()
  }

  return ref.current
}

将其移植到reasonml似乎很难，我必须使用两次类型转换，理想的方式是什么？

external toAny: 'a => 'b = "%identity";
external toBool: 'a => bool = "%identity";

let useConstant = (fn: unit => 'a) => {
  let ref: React.Ref.t('a) = toAny(React.useRef());
  if (!toBool(React.Ref.current(ref))) {
    React.Ref.setCurrent(ref, fn());
  };
  React.Ref.current(ref);
};

Answer 1

如果我正确理解了钩子的用途，它实际上只是对React.useMemo 的重新实现。但是为了学习，这里有一个应该可以工作的实现。

let useLazy = (fn: unit => 'a): 'a => {
  let ref = React.useRef(None);

  switch (React.Ref.current(ref)) {
  | Some(value) => value
  | None =>
    let value = fn();
    React.Ref.setCurrent(ref, Some(value));
    value;
  };
};

它使用the option type，它是专门为这种情况设计的。如果没有值，我们使用options None 值表示，如果有值我们使用Some。我们没有使用 if 和 JavaScript 语义不清楚的真实性概念，而是使用 option 上的 pattern match 使用 switch 发现它是 None 并且需要计算值，或者 Some 得到价值。

option 和模式匹配的使用在 Reason 代码中非常常见，因此如果需要，您应该使用上面提供的链接了解更多详细信息。

请注意，您也可以为此使用Lazy。但这并不常用，因此学习起来也不太有用。