如何让海龟在海龟从三个方向到达的斑块的交点处转弯

Question

我已经创建了人们（乌龟）随机移动的道路（灰色区域）。在交叉点（白色斑块），我让它们（海龟）可能会或可能不会转向他们的航向。以我编码的方式，如果他们的标题是 90 和 270，它工作正常。但是，如果航向为 0，则几乎 95% 的时间他们会返回 (180) 而不是向左 (270) 或向右 (90)。代码中没有错误。我只是想知道，我们能否以其他方式编码，使 0 航向的海龟也可以像其他两个航向一样在所有三个转弯中都有 50% 的机会。

以下是我的代码：

breed [people person]
globals [ streets intersections head]
people-own [ speed direction]
patches-own [ intersection? ]

to setup
   clear-all
   ask patches [set pcolor green
                set intersection? false]
   setup-street
   setup-people
end

to setup-street
  ;set streets patches with [ (( pxcor < max-pxcor and pxcor > min-pxcor ) ;and (pycor = 4) or (pxcor = 0 and ( pycor > min-pycor and pycor < 4))]

  set streets patches with [ (( pxcor < max-pxcor and pxcor > min-pxcor ) and (pycor = 4 or pycor = 5)) or ((pxcor = 0 or pxcor = 1) and ( pycor > min-pycor and pycor < 4))]

  set intersections patches with [ (pxcor = 0 or pxcor = 1) and (pycor = 4 or pycor = 5)]

   ask streets [set pcolor gray]
   ask intersections [ set pcolor white]
   setup-intersection
end

to setup-intersection
     ask intersections [ set intersection? true]
end

to setup-people
   ask n-of No-of-person patches with [ pcolor = gray or pcolor = white] [
     sprout-people 1 [
           set color brown
           set size 1
           set shape "person"
           set speed 0.01 + random-float 0.9
           set direction random 2
           set-default-headings direction
      ]
   ]
end

to set-default-headings [ direct]
   if direct = 0 [
     ;ask people with [ ( pxcor < max-pxcor and pxcor > min-pxcor ) and  pycor = 4 ]
     ask people with [ (pxcor < max-pxcor and pxcor > min-pxcor ) and (pycor  = 4 or pycor = 5)]
      [ set head random 2
          if head = 0 [ set heading 90]
          if head = 1 [ set heading 270]
      ]
    ]

   if direct = 1 [
   ;ask people with [ pxcor = 0 and ( pycor > min-pycor and pycor < 4) ]
     ask people with [(pxcor = 0 or pxcor = 1) and ( pycor > min-pycor and pycor < 4)]
      [ set head random 2
          if head = 0 [ set heading 0]
          if head = 1 [ set heading 180]
      ]
   ]
 end

 to go
    ask people [ fd speed 
                 check-intersection
                 check-end]
 end

 to check-intersection
      if intersection? [
           if heading = 90 [if random 20 < 10 [ set heading 180] ]
           if heading = 270 [if random 20 < 10 [ set heading 180] ]
           if heading = 0 [ let new-heading random 2
                         if (new-heading = 0) [rt 90 ]
                         if (new-heading = 1) [lt 90 ] ]
           ]
  end

  to check-end
      ask people [ if [pcolor] of patch-ahead 1 = green [set heading  [heading] of self - 180 ] ]
  end

Answer 1

我以减慢速度运行您的代码并创建了一个人。我认为问题不在于您的随机方向创建-速度意味着该人在交叉路口花费了多个刻度，并且仅在生成的随机方向再次将它们向下移动时才离开。例如，代理以 0 的航向进入交叉路口并获得随机航向 90，因此向右移动一段距离

解决此问题的一种方法是创建一个计数器/标志。到达交叉路口时设置，如果标志仍然设置，则不检查交叉路口。

to go
  ask people [ fd speed
               set just-turned max (list 0 just-turned - 1) 
               check-intersection
               check-end]
end

to check-intersection
  if intersection? and just-turned = 0 [
       set just-turned 1 / speed + 1
       if heading = 90 [if random 20 < 10 [ set heading 180] ]
       if heading = 270 [if random 20 < 10 [ set heading 180] ]
       if heading = 0 [ let new-heading random 2
                     if (new-heading = 0) [rt 90 ]
                     if (new-heading = 1) [lt 90 ] ]
       ]
end

顺便说一句，当我进行此测试时，我还注意到在您的 T 形街道底部创建的至少一些（可能是所有）代理的标题为 45。

另外，一些代码建议，而不是像

set head random 2
  if head = 0 [ set heading 0]
  if head = 1 [ set heading 180]

1/ 你可以使用（所以它不会检查每个 if 语句）

set head random 2
  ifelse head = 0 [ set heading 0] [ set heading 180]

2/ 或（因此您不必为随机数创建局部变量）

set heading ifelse-value (random 2 = 0) [0] [180]

3/ 或（因此您可以针对不同的情况使用不同的命令）

ifelse random 2 = 0 [ set heading 0] [ set heading 180]

4/或（因为本例中存在数学关系）

set heading random 2 * 180

在这种情况下，数字 4 是最好的，但数字 3 也适用于您有不同命令的部分（如 [lt 90][rt 90]）