当控制值是离散的时，是否可以使用一些“上一个-下一个”按钮而不是滑块，如下例所示？
我发现 Manipulator 很丑，如果可能的话，我想要一些 Setter 类型的。
Manipulate[
Graphics[
{
Rectangle[{1, 1}, {3, 3}],
Circle[{where, 2}, 1]
},
PlotRange -> {{0, 11}, {0, 3}}, ImageSize -> {300, 60}
],
{where, 1, 10, 1, Slider}
]
【问题讨论】：
标签： slider controls wolfram-mathematica
您可以像这样使用Button 创建自己的控件：
Manipulate[
Graphics[
{Rectangle[{1, 1}, {3, 3}],
Circle[{where, 2}, 1]},
PlotRange -> {{0, 11}, {0, 3}},
ImageSize -> {300, 60}
],
{{where, 1, ""},
Button["Prev", where = Max[1, where - 1], Appearance -> "Palette",
ImageSize -> {50, Automatic}] &},
{{where, 1, ""},
Button["Next", where = Min[10, where + 1], Appearance -> "Palette",
ImageSize -> {50, Automatic}] &},
ControlPlacement -> Left]
【讨论】：
据我所知，如果没有为 Manipulate 指定控件，那么 Mathematica 将根据给定的值决定使用什么控件。这通常是 Manipulator 控件，它不同于 Slider 控件（在您的示例中），因为可以扩展控件以使用前进/后退、播放功能等。这些可能就足够了：
Manipulate[
Graphics[{Rectangle[{1, 1}, {3, 3}], Circle[{where, 2}, 1]},
PlotRange -> {{0, 11}, {0, 3}}, ImageSize -> {300, 60}], {where, 1,
10, 1, Manipulator, Appearance -> "Open",
AppearanceElements -> {"StepLeftButton", "StepRightButton"}}]
关于 SO 的一个相当近期的问题解决了如何使用以下选项从一开始就为操纵器显示这些离散按钮：Appearance-> Open
How to show the animation control by default.
编辑： 您还可以指定要显示的离散按钮，例如只需使用
的步骤左右按钮AppearanceElements -> {"StepLeftButton", "StepRightButton"}
我添加到上面的代码示例中。
实际上，一个更好更简单的选择是使用触发控件来隐藏滑块。
Manipulate[
Graphics[{Rectangle[{1, 1}, {3, 3}], Circle[{where, 2}, 1]},
PlotRange -> {{0, 11}, {0, 3}}, ImageSize -> {300, 60}], {where, 1,
10, 1, ControlType -> Trigger,
AppearanceElements -> {"StepLeftButton", "StepRightButton"}}]
【讨论】：
正如 Yoda 所示，Button 可用于 Manipulate 中的 Next 和 Previous 按钮。这种按钮通常用于通过有限范围的对象。在此范围的开头和结尾处，应分别禁用 Previous 和 Next 按钮。为了让它工作，可以使用按钮属性Enabled，因为它的动作依赖于一个交互变化的值，所以需要Dynamic。下面的玩具示例展示了它是如何工作的。
示例代码：
votePictures[picturesInput_] :=
DynamicModule[{pictures = picturesInput, status, i},
status = Table["Not Voted", {Length[pictures]}];
i = 1;
Panel[
Row[
{
Dynamic[Show[pictures[[i]], ImageSize -> 256]], Spacer[72 0.7],
Column[
{
Row[{Style["Status ", FontFamily -> "Arial-Bold"],
SetterBar[
Dynamic[status[[i]]], {"No response", "Ugly", "Nice"}]}
], , ,
Row[{
Button["Previous", i -= 1, Enabled -> (i > 1)],
Button["Next", i += 1, Enabled -> (i < Length[pictures])]}
] // Dynamic,
Row[
{
Style["Picture ", FontFamily -> "Arial-Bold"],
Slider[Dynamic[i], {1, Length[pictures], 1},Appearance -> "Labeled"]
}
], , ,
Button["Save results", (*Export code here *)]
}
] // Framed
}
], ImageSize -> 750
]
]
pictures = ExampleData[#] & /@ ExampleData["TestImage"]
votePictures[pictures]
【讨论】：