WHERE IN 条件不接受字符串值

Question

我在 PL/Sql 过程中动态构造一个名为 user_data 的字符串，方法是附加 USERNAME、单引号 (') 和逗号 (,) 形式的

'abc123','xyz456','pqr789'

但是当我将此字符串传递给 SELECT 语句的 WHERE IN 条件时

SELECT * FROM table_name WHERE USERNAME IN (user_data)

它正在引发 NO_DATA_FOUND 异常。

另一方面，如果我的字符串只包含一个不带引号的用户，它能够找到该用户并显示所需的输出。

字符串user_data的数据类型是varchar2。

Answer 1

你的选择语句

SELECT * FROM table_name WHERE USERNAME IN (user_data)

将被视为

SELECT * FROM table_name WHERE USERNAME = 'abc123','xyz456','pqr789'

这是不正确的。

另一种选择是

SELECT * FROM table_name WHERE INSTR(user_data, USERNAME) > 0

Answer 2

您可以使用集合来做到这一点：

CREATE TYPE VARCHAR2s_Table IS TABLE OF VARCHAR2(100);
/

然后像这样输入您的数据：

SELECT *
FROM   table_name
WHERE  user_data MEMBER OF VARCHAR2s_Table( 'abc123','xyz456','pqr789' );

或者：

您可以创建一个函数来拆分数据并生成集合：

CREATE TYPE VARCHAR2_TABLE AS TABLE OF VARCHAR2(4000);
/

CREATE OR REPLACE FUNCTION split_String(
  i_str    IN  VARCHAR2,
  i_delim  IN  VARCHAR2 DEFAULT ','
) RETURN VARCHAR2_TABLE DETERMINISTIC
AS
  p_result       VARCHAR2_TABLE := VARCHAR2_TABLE();
  p_start        NUMBER(5) := 1;
  p_end          NUMBER(5);
  c_len CONSTANT NUMBER(5) := LENGTH( i_str );
  c_ld  CONSTANT NUMBER(5) := LENGTH( i_delim );
BEGIN
  IF c_len > 0 THEN
    p_end := INSTR( i_str, i_delim, p_start );
    WHILE p_end > 0 LOOP
      p_result.EXTEND;
      p_result( p_result.COUNT ) := SUBSTR( i_str, p_start, p_end - p_start );
      p_start := p_end + c_ld;
      p_end := INSTR( i_str, i_delim, p_start );
    END LOOP;
    IF p_start <= c_len + 1 THEN
      p_result.EXTEND;
      p_result( p_result.COUNT ) := SUBSTR( i_str, p_start, c_len - p_start + 1 );
    END IF;
  END IF;
  RETURN p_result;
END;
/

那么你可以这样做：

SELECT *
FROM   table_name
WHERE  user_data MEMBER OF split_String( 'abc123,xyz456,pqr789', ',' );

或：

SELECT *
FROM   table_name
WHERE  user_data MEMBER OF split_String( TRIM( '''' FROM '''abc123'',''xyz456'',''pqr789''' ), ''',''' );

Answer 3

您可以在 IN 子句中使用类似这样的动态字符串：

SQL> declare
  2      user_data varchar2(1000);
  3      vSQL      varchar2(2000);
  4      type      tabUser is table of varchar2(16);
  5      outData   tabUser;
  6  begin
  7      user_data := '''abc'', ''123'', ''zzz''';
  8      --
  9      vSQL := 'select userName from table_name where username in (' || user_data || ')';
 10      --
 11      execute immediate vSQL bulk collect into outData;
 12      --
 13      dbms_output.put_line('user_data: ' || user_data);
 14      for i in outData.first .. outData.last loop
 15          dbms_output.put_line('User: ' || outData(i));
 16      end loop;
 17  end;
 18  /
user_data: 'abc', '123', 'zzz'
User: abc
User: 123

PL/SQL procedure successfully completed.

SQL> select * from table_name;

USERNAME
----------------
abc
ABC
123

在这种情况下，无论您是否有一个或多个用户名，您都必须在字符串中使用带引号的名称。

Answer 4

它不是那样工作的。你的表达式等于

SELECT * FROM table_name WHERE USERNAME = '''abc123'', ''xyz456'', ''pqr789''';

这就是没有找到结果的原因。

你可以这样做，以达到欲望效果：

SELECT * FROM table_name WHERE user_data like '%''' || USERNAME || '''%';

但它不会是一样的。