“*variable* = Dir”导致错误：循环文件时出现“无效的过程调用或参数”

Question

我正在尝试制作一个循环遍历文件并将名称查找到 Excel 工作表中的脚本。

Option Compare Text
Option Explicit
Sub SortVerkoops()
Dim verkoop As String, verkoopnoex As String, gbref As String, orderstatusname As String, gbyear As String, dealer As String, rootorderpath As String, orderpath As String, foldername As String
Dim gbrefv As String
Dim orders As Range
Dim orderstatus As String
Dim wb As Workbook

orderstatusname = Dir("D:\reece\Documents\Sort sales orders into folders\Staff\Order status\Order status 2021.xlsx")

orderstatus = "D:\reece\Documents\Sort sales orders into folders\Staff\Order status\Order status 2021.xlsx"
verkoop = Dir("D:\reece\Documents\Sort sales orders into folders\Staff\Verkoops\*")

Workbooks.Open Filename:=orderstatus, ReadOnly:=True

Set wb = Workbooks(orderstatusname)
Set orders = wb.Sheets("UK Orders").Range("$A:$B")

Do While Len(verkoop) > 0
    Debug.Print "##########"
    Debug.Print verkoop
    verkoopnoex = Replace(verkoop, ".docx", "")
    gbref = Trim(Replace(verkoopnoex, "Sales Order", ""))
    gbyear = Left(gbref, InStr(gbref, "-") - 1)
    gbyear = (gbyear & "-####")
    ThisWorkbook.Sheets(1).Range("_gbref") = gbref
    Debug.Print gbrefv
    Debug.Print gbref
    Debug.Print gbyear
    dealer = ThisWorkbook.Sheets(1).Range("_dealer").Value
    Debug.Print dealer
    rootorderpath = ("D:\reece\Documents\Sort sales orders into folders\Staff\Customer orders\" & dealer & "\" & gbyear)
    'foldername = Dir(rootorderpath & "\" & gbref & "*")
    orderpath = (rootorderpath & "\" & foldername)
    Debug.Print foldername
    Debug.Print orderpath
    verkoop = Dir
    Debug.Print verkoop
    Debug.Print "##########"
Loop


End Sub

我唯一遇到的麻烦是当我将变量重新定义为 = Dir 以重置文件时，我收到此错误：

该错误仅在这段代码处于活动状态时显示：

我在尝试排除故障时遇到了麻烦。感谢您的帮助，谢谢！

编辑 11/06/2021：非常感谢 Tim Williams 的解决方案。如果有人想要我的工作代码，请告诉我，我可以清理并提供它。

Answer 1

您不能嵌套调用Dir() - 您必须在开始另一个循环之前完成一个循环。

您可以改为这样做：

Sub Tester()

    Dim colFiles As Collection, fName
    
    Set colFiles = DirMatches("C:\Tester\", "*.xls*")
    For Each fName In colFiles
        Debug.Print fName
    Next fName
    
End Sub

'Run a Dir loop on `FolderPath` and return all matches in a collection
'   of filenames (or full path) where filename matches `pattern` 
Function DirMatches(ByVal folderPath As String, pattern As String)
    Dim col As New Collection, f
    If Right(folderPath, 1) <> "\" Then folderPath = folderPath & "\"
    f = Dir(folderPath & pattern)
    Do While Len(f) > 0
        col.Add f                  'filename only
        'col.Add folderPath & f    'full path
        f = Dir()
    Loop
    Set DirMatches = col
End Function