后台工作者可以共享功能吗

Question

我有一个相当复杂的窗口窗体应用程序，它管理着 2 个后台工作线程。一切都按预期运行，但我发现自己写了两次，每个后台工作人员一次，我不确定这是否需要。例如，我在其中一个 Do_Work 例程中：

Do While ThisQueue.FIleList.Count > 0
  ..Do some work..
  Call Worker1DoSomething(SomeVar)
  ..Do more work..
Loop

在第二个后台工作人员的 Do_Work 例程中，我有：

Do While ThisQueue.FileList.Count > 0
  ..Do some work..
  Call Worker2DoSomething(SomeVar)
  ..Do more work..
Loop

我可以让两个 Do_Work 例程都调用 1 个函数而不把事情搞砸吗？而不是两个函数：Worker1DoSomething(byval thisvar as string) 和 Worker2DoSometing(byval thisvar as string) 只有 1 个函数 WorkerFunctionDoSomething(byval thisvar as string)？

我问的最大原因是我有 8 个函数，实际上是从 Do_Work 例程调用的 4 个函数，这将大大简化代码。其中一个函数将数据写入 SQL 服务器，这也是我开始采用这种方法的主要原因。

提前感谢您的任何帮助或建议！ 弗雷德

Answer 1

你当然可以做到。与任何事件处理程序一样，在DoWork 事件处理程序内部，sender 参数是引发事件的对象。如果您在每个BackgroundWorker 与您希望它使用的数据和/或您要执行的方法之间建立关系，您可以使用sender 来获取该数据和/或方法并利用它们。一种方法是使用 Dictionary 和 BackgroundWorker 对象作为键：

Private ReadOnly workMethodsByWorker As New Dictionary(Of BackgroundWorker, Action(Of Object)) From {{BackgroundWorker1, AddressOf Method1},
                                                                                                     {BackgroundWorker2, AddressOf Method2}}

Private data As Object

Private Sub BackgroundWorkers_DoWork(sender As Object, e As DoWorkEventArgs) Handles BackgroundWorker1.DoWork,
                                                                                     BackgroundWorker2.DoWork
    Dim worker = DirectCast(sender, BackgroundWorker)
    Dim method = workMethodsByWorker(worker)

    method(data)
End Sub

Private Sub Method1(data As Object)
    '...
End Sub

Private Sub Method2(data As Object)
    '...
End Sub

另一种选择是定义您自己的类，该类继承BackgroundWorker，并为要执行的方法添加一个属性，并使用该类而不是标准的BackgroundWorker：

Imports System.ComponentModel

Public Class BackgroundWorkerEx
    Inherits BackgroundWorker

    Public Property WorkMethod As Action(Of Object)

End Class

Private data As Object

Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
    BackgroundWorkerEx1.WorkMethod = AddressOf Method1
    BackgroundWorkerEx2.WorkMethod = AddressOf Method2
End Sub

Private Sub BackgroundWorkers_DoWork(sender As Object, e As DoWorkEventArgs)
    Dim worker = DirectCast(sender, BackgroundWorkerEx)
    Dim method = worker.WorkMethod

    method(data)
End Sub

Private Sub Method1(data As Object)
    '...
End Sub

Private Sub Method2(data As Object)
    '...
End Sub