如何用不同的颜色绘制立方体每个面的每个角？

Question

我是 GLSL 方面的新手，我一直在努力寻找一种方法来为立方体的所有顶点着色不同的颜色。每个面有 4 个顶点，一个立方体有 6 个面，所以 6 * 4 = 24。但我每个角只能绘制 1 种颜色。

顶点着色器：

#version 330

uniform mat4 u_m_matrix;
uniform mat4 u_vp_matrix;

layout (location=0) in vec3 a_position;
layout (location=1) in vec3 a_normal;

out vec3 normal;

void main()
{
    normal = a_position;
    gl_Position = u_vp_matrix * u_m_matrix * vec4(a_position, 1.0);
}

片段着色器：

#version 330

in vec3 normal;

out vec4 fragColor;

void main() {

    fragColor = vec4(normal, 1.0);
 }

结果：

Answer 1

如果你想用不同的颜色为每个面着色并且你想找到一个着色器内的解决方案，一个可能性是为立方体的片段着色，这取决于顶点坐标的分量与最大数量.

将顶点坐标传递给片段着色器：

#version 330

uniform mat4 u_m_matrix;
uniform mat4 u_vp_matrix;

layout (location=0) in vec3 a_position;
//layout (location=1) in vec3 a_normal;

out vec3 vertPos;

void main()
{
    vertPos     = a_position;
    gl_Position = u_vp_matrix * u_m_matrix * vec4(a_position, 1.0);
}

找到绝对值最大的顶点坐标的分量并选择颜色：

#version 330

in vec3 vertPos;

out vec4 fragColor;

void main() {

    vec3 posAbs  = abs(vertPos);
    vec3 color   = step(posAbs.yzx, posAbs) * step(posAbs.zxy, posAbs); 
    color       += (1.0 - step(color.zxy * vertPos.zxy, vec3(0.0)));

    fragColor = vec4(color, 1.0);
}

---

如果法线向量是面法线，那么使用法线向量还有一个更简单的解决方案：

将法线向量传递给片段着色器：

#version 330

uniform mat4 u_m_matrix;
uniform mat4 u_vp_matrix;

layout (location=0) in vec3 a_position;
layout (location=1) in vec3 a_normal;

out vec3 normal;

void main()
{
    normal      = a_normal;
    gl_Position = u_vp_matrix * u_m_matrix * vec4(a_position, 1.0);
}

根据法线向量计算颜色：

#version 330

in vec3 normal;

out vec4 fragColor;

void main() {

    vec3 color = abs(normal.xyz) + max(normal.zxy, 0.0);
    fragColor  = vec4(color, 1.0);
}

---

[...] 所以我需要 24 种颜色。 [...]

在这种情况下，我建议以下解决方案。

#version 330

in vec3 vertPos;

out vec4 fragColor;

void main() {

    vec3 posAbs = abs(vertPos);
    vec3 color  = (step(posAbs.yzx, posAbs) * step(posAbs.zxy, posAbs) +
                   step(0.0, vertPos.yzx)) * 0.5;
    fragColor   = vec4(color, 1.0);
}