循环的批处理脚本不起作用

Question

您好，这个批处理脚本有问题，它不起作用：

set OUTdir=../output

@echo on
:: ex  nFun  tol  M Nt print
::     nFun: numero di funzione test [1,...,7]
::     tol:  error tolerance
::     M:    ridotta di ordine 2*M+1
::     Nt:   Numero di valori della funzione inversa
::     print: 1 (to print the header) 2(to print the end of the header) 0 or nothing( to print just output values)

SET /A y=1
set /A max=16384

FOR /L %%x IN (32,1,%max%) DO (
 IF  %y% EQU 1 (
  ex 1 1e-9 %%x 25  %y% > %OUTdir%\out_F01_times_9.txt   
  set /A y=0) 
  ELSE (
  if  %y% EQU 0 if  %%x LSS %max% (  
    ex 1 1e-9 %%x 25 0  > %OUTdir%\out_F01_times_9.txt )
   ELSE (
    ex 1 1e-9 %%x 25 2  > %OUTdir%\out_F01_times_9.txt ) )
)

ex 是一个程序，其他数字是命令行参数。

你能帮帮我吗？我正在尝试创建一个批处理来执行具有不同参数的 ex 程序。

错误是ELSE IS NOT RECOGNIZED AS外部或内部命令

Answer 1

您必须将您的 ELSE 子句与您的 IF-clause 操作的近括号放在同一行（我通常将其视为 ) ELSE ( 单独一行）：

set OUTdir=../output

@echo on
:: ex  nFun  tol  M Nt print
::     nFun: numero di funzione test [1,...,7]
::     tol:  error tolerance
::     M:    ridotta di ordine 2*M+1
::     Nt:   Numero di valori della funzione inversa
::     print: 1 (to print the header) 2(to print the end of the header) 0 or nothing( to print just output values)

SET /A y=1
set /A max=16384

FOR /L %%x IN (32,1,%max%) DO (
 IF  %y% EQU 1 (
  ex 1 1e-9 %%x 25  %y% > %OUTdir%\out_F01_times_9.txt   
  set /A y=0 
  ) ELSE (
  if  %y% EQU 0 if  %%x LSS %max% (  
    ex 1 1e-9 %%x 25 0  > %OUTdir%\out_F01_times_9.txt
    ) ELSE (
    ex 1 1e-9 %%x 25 2  > %OUTdir%\out_F01_times_9.txt
    )
  )
)

你也不需要/ASET将一个变量转换为一个简单的数字； SET /A 允许在 SET 命令中进行数学运算，例如，SET /A Y=%M%*4 将 Y 设置为 M 中存储的数字的四倍。

Answer 2

正如其他答案/cmets 所示，您需要根据 C-K&R 样式放置右括号，而不是 Lisp 样式，如Indent Style Wikipedia 文章的大括号放置部分所示.

但是，您的代码过于复杂。您在第一个IF %y% EQU 1 中使用y 变量只是为了执行第一个ex 命令一次（顺便说一句，需要延迟扩展才能正常工作），而您使用最后一个if %%x LSS %max% 只是为了执行最后ex 命令一次。使用此代码可能会得到相同的结果，不需要任何 if，因此它应该运行得更快：

set OUTdir=../output


SET /A max=16384, maxM1=max-1

(  ex 1 1e-9 32 25 1
   FOR /L %%x IN (33,1,%maxM1%) DO (
      ex 1 1e-9 %%x 25 0
   )
   ex 1 1e-9 %max% 25 2
) > %OUTdir%\out_F01_times_9.txt

请注意，您也可以将多个命令括在括号中，并为它们全部使用一个重定向；这种方法不仅看起来更清晰，而且更高效/更快。