将数据导出到文件

Question

我有一种情况需要将标题行信息放入 CSV 文件中。

之后，我需要向该文件附加 3 个不同列号的查询。

目前有这个逻辑，但是TransferText 行覆盖了我之前放在文件中的内容：

Dim fldr As String

Dim dlg As Office.FileDialog
Set dlg = Application.FileDialog(msoFileDialogFolderPicker)
With dlg
    .AllowMultiSelect = False
    .Title = "Select a Folder:"
    .Filters.Clear
    '.Filters.Add "CSV Files", "*.csv"

    If .show = True Then
        fldr = .SelectedItems(1)
    End If
End With
GC dlg

'TODO: Remove after Debugging is complete
RaiseAlert "Folder chosen: " & fldr
'-----------------------------------------

Dim file As String
file = fldr & "\Export_DelaGet_" & Format(Now(), "yyyy_mm_dd") & ".csv"

'TODO: Remove after Debugging is complete
RaiseAlert "File: " & file
'-----------------------------------------

'TODO: OpenFile and output the header line
Open file For Output As #1
Print #1, """SYS"",""Some Data""" & vbCrLf
Close 1

'Output Query/View Results to file
DoCmd.TransferText acExportDelim, "MstPrc_Spec", "vwMasterPrices_Output", file, False

通过 RecordSet 遍历查询对我来说会更好还是我错过了 TransferText 中的某些内容？

Answer 1

除非其他人可以为我提供更好的执行此操作的方法，否则这是我目前所拥有的。

Dim fldr As String

Dim dlg As Office.FileDialog
Set dlg = Application.FileDialog(msoFileDialogFolderPicker)
With dlg
    .AllowMultiSelect = False
    .Title = "Select a Folder:"
    .Filters.Clear
    '.Filters.Add "CSV Files", "*.csv"

    If .show = True Then
        fldr = .SelectedItems(1)
    End If
End With
GC dlg

'TODO: Remove after Debugging is complete
'    RaiseAlert "Folder chosen: " & fldr
'-----------------------------------------

Dim file As String
file = fldr & "\Export_" & Format(Now(), "yyyy_mm_dd") & ".csv"

'TODO: Remove after Debugging is complete
'    RaiseAlert "File: " & file
'-----------------------------------------

'TODO: OpenFile and output the header line
Open file For Output As #1
Print #1, """SYS"",""Some Data""" & vbCrLf
Close 1

Open file For Append As #2
Dim rst As DAO.Recordset, str As String

'Append MasterPrices
Set rst = CurrentDb.OpenRecordset("vwMasterPrices_Output")
If rst.RecordCount > 0 Then
    Do While Not rst.EOF
        str = """" & rst(0) & """,""" & rst(1) & """,""" & rst(2) & """,""" & rst(3) & """,""" & rst(4) & """," & Format(rst(5), "##0.00")

        Print #2, str

        'Move Next
        rst.MoveNext
    Loop
End If

'Append GroupPrice
Set rst = CurrentDb.OpenRecordset("vwGroupPrice_Output")
If rst.RecordCount > 0 Then
    Do While Not rst.EOF
        str = """" & rst(0) & """,""" & rst(1) & """,""" & rst(2) & """," & Format(rst(3), "##0.00")

        Print #2, str

        'Move Next
        rst.MoveNext
    Loop
End If

'Append GroupLocations
Set rst = CurrentDb.OpenRecordset("vwGroupLocations_Output")
If rst.RecordCount > 0 Then
    Do While Not rst.EOF
        str = """" & rst(0) & """,""" & rst(1) & """," & rst(2)

        Print #2, str
        'Move Next
        rst.MoveNext
    Loop
End If

GC rst
Close 2

不幸的是TransferText 方法执行File-Output 而不是File-Append 操作。因此，TransferText 之前文件中的所有内容都将被清除并替换为方法的输出。

是的，我必须在 CSV 的字符串周围设置文本限定符。