访问 VBA - 防止重复输入答案

【问题标题】：Access VBA - prevent duplicate entry访问 VBA - 防止重复输入
【发布时间】：2016-04-14 06:33:47
【问题描述】：

我试图通过在更新前检查条目来避免 Access 内置 msgbox 输入重复记录。代码有效，但有一个大问题——你不能再编辑这些记录了。任何方式来完成这两个 - 允许编辑并避免访问 msgbox ？

Private Sub Form_BeforeUpdate(Cancel As Integer)

Dim rs As Recordset
Set rs = CurrentDb.OpenRecordset("MyTable", dbOpenDynaset)

If Data_Changed Then 'Variable of Boolean that is set to True in Dirty event

     If Not IsNull(ID_Field) Then

         If MsgBox("You have done changes. you wish to save? ?" & vbCrLf & vBCrLf & "Click Yes for saving changes or NO for Undoing changes ! " & _
         , vbQuestion + vbOKCancel + vbDefaultButton1) = vbOK Then

             rs.FindFirst "ID = " & Me.ID_Field

             If Not rs.NoMatch Then
                 Cancel = True
                 MsgBox "Error. You cannot add another record with same ID!", vbCritical
                 DoCmd.RunCommand acCmdUndo
                 Exit Sub
             End If


         Else

             DoCmd.RunCommand acCmdUndo

         End If

      Else

          MsgBox "Error. you cannot save record with blank ID !", vbCritical

          DoCmd.SetWarnings False
          If Me.Dirty Then Me.Undo
          DoCmd.SetWarnings True

          Exit Sub

      End If

      Me.ID_Field.Locked = True
      Me.Other_Field.Locked = True

End If

End Sub

【问题讨论】：

我明白了。您的ID_Field 是主键吗？通常，PK 应该对用户不可见，并且绝对不能由用户编辑。正如您所发现的，它会产生问题。如果是PK，有什么理由让用户可以编辑吗？如果没有，您可以使用 PK 来识别当前记录并将其从搜索中排除。
@Andre，不。 ID_Field 不是主键。并且 PK 对用户是不可见的。但是 ID 和 ID_Field（具有完全不同的名称 - 我搞砸了）都将索引设置为无重复项。但是，将 Id_Field 更改为 Indexed No 不会改变任何内容。
如何从搜索中排除记录，但如果输入具有相同 Id_Field 的新记录，则保持代码运行？

标签： ms-access vba

【解决方案1】：

假设您的主键列是myPK。

要针对除当前记录之外的所有记录检查 ID_Field，请不要使用 Recordset 和 FindFirst，而是使用 DLookup。

Dim TestID as Long
TestID = Nz(DLookup("ID_Field", "MyTable", "ID_Field = " & Me.ID_Field & _
                    " AND myPK <> " & Nz(Me.myPK, 0)), 0)
If TestID > 0 Then
    ' Dupe
Else
    ' ok
End If

您可能需要将myPK 作为不可见的文本框添加到表单中，以便能够读取其值。

【讨论】：

伟大的安德烈，这行得通！真是一场噩梦，我尝试了数千种变化，但没有任何效果。非常感谢！
Andre，如果需要两个字段的组合呢？像 ID_Field 和 SomeOther_Field ？只需在 Me.ID_Field 之后添加它？
@LuckyLuke82：DLookup 的第三个参数就像一个 WHERE 子句，你可以建立任何你喜欢的标准。例如"ID_Field = " & Me.ID_Field & " AND SomeOther_Field = " & Me.SomeOther_Field & " AND myPK <> " & Nz(Me.myPK, 0)。对于文本条件，请将它们括在 '' 中。
我已经尝试过了，但似乎它不起作用：Nz(DLookup("ID_Field", "JoinTable", "ID_Field = " & Me.ID_Field & Another_Field & _ " AND PK_JoinTable " & Nz(Me.PK_JoinTable, 0)), 0)。但是，这是一个 Join 表，必须检查 2 FK 的索引。
@LuckyLuke82：在查询设计编辑器中构建您的查询，切换到 SQL 视图，并使用 WHERE 子句作为模板来构建 DLookup 参数。

【解决方案2】：

“快照”获取当前状态的记录，例如检查。它们是只读的。

要打开记录集读/写，请使用dbOpenDynaset

【讨论】：

我试过了，但这并不能解决问题，记录仍然无法编辑。
请在您尝试编辑记录的位置显示完整代码。
Paul，我用于编辑记录的代码是一个简单的按钮，可以以连续形式解锁字段。

【解决方案3】：

为了防止内置消息，最好使用Form.OnError事件。
见：https://msdn.microsoft.com/en-us/library/office/ff836345.aspx

例如像这样：

Private Sub Form_Error(DataErr As Integer, Response As Integer)

    ' Error 3022 = "Cannot add a duplicate value because of a key constraint..."
    If DataErr = 3022 Then
        MsgBox "Your duplicate warning", vbExclamation
        ' Remove duplicate ID and set focus into ID control
        Me!ID_Field = Null
        Me!ID_Field.SetFocus
        ' Dont't show default error message
        Response = acDataErrContinue
    Else
        ' Other errors: show default error message
        Response = acDataErrDisplay
    End If

End Sub

【讨论】：

谢谢。我之前已经遇到过这样的事情，但仍然存在一个问题 - 当您仍然以连续形式在同一记录中并尝试通过 DoCmd.RunCommand acCmdSaveRecord 保存记录时，仍然会弹出错误“3022”。这可以通过一个简单的错误句柄来解决 - If err.number=3022 Then...但是，当您尝试以连续形式继续另一条记录时，表单错误代码会起作用。但是 - 我试图只用一个代码来解决这个问题，这就是我改变一切的原因。