无法为此类型编写 Show 实例

Question

考虑以下类型声明：

data Foobar x = Foo (x (Foobar x))

现在为此编写一个Show 实例。我敢！

我随便写了deriving Show，期待GHC 能做到。但它抱怨说它做不到。 “可怜的傻瓜”，我想，然后自己来定义它。但是...嗯...哦，实际上这很有趣...显然Foobar x 仅在x y 可显示为可显示y 时才显示...或...类似的东西...啊啊！

现在我确定我不可能是第一个定义这种类型的人。我不能成为第一个想要Show 实例的人。所以一定有人想出了如何做到这一点。

Answer 1

如果您只是指定明显的约束——并添加一些必要的语言编译指示——一切都会正常工作。要使 Foobar 可显示，Foo 的字段必须是可显示的，因此我们需要 Show (x (Foobar x)) 约束。如果我们要求这样做，一切都会顺利进行：

{-# LANGUAGE FlexibleContexts, UndecidableInstances, StandaloneDeriving #-}

data Foobar x = Foo (x (Foobar x))
deriving instance Show (x (Foobar x)) => Show (Foobar x)

然后：

λ> print $ Foo [Foo [], Foo [Foo []]]
Foo [Foo [],Foo [Foo []]]
λ> data SL a = S String | L [a] deriving Show
λ> print $ Foo (L [Foo (S "a"), Foo (L [Foo (S "b"), Foo (L []), Foo (S "c")])])
Foo (L [Foo (S "a"),Foo (L [Foo (S "b"),Foo (L []),Foo (S "c")])])

我有点惊讶这能奏效，但也不过分 :-)

---

顺便说一句，如果您尝试将 Show 派生为 Foobar，这正是 GHC 对您的要求：

λ> data Foobar x = Foo (x (Foobar x)) deriving Show

<interactive>:2:45:
    No instance for (Show (x (Foobar x)))
      arising from the first field of ‘Foo’ (type ‘x (Foobar x)’)
    Possible fix:
      use a standalone 'deriving instance' declaration,
        so you can specify the instance context yourself
    When deriving the instance for (Show (Foobar x))

我们所要做的就是使用StandaloneDeriving 并准确指定该约束！

---

另外，需要明确的是，StandaloneDeriving 部分是可选的——它没有做任何魔法，而且手动编写实例并不难：

instance Show (x (Foobar x)) => Show (Foobar x) where
  showsPrec p (Foo x) = showParen (p > app_prec) $
                          showString "Foo " . showsPrec (app_prec + 1) x
    where app_prec = 10 :: Int

Answer 2

以下是不带扩展名的方法：

data Foobar x = Foo (x (Foobar x))

class Show1 f where
    showsPrec1 :: Show a => Int -> f a -> ShowS

instance Show1 f => Show (Foobar f) where
    showsPrec n (Foo v) = ("Foo " ++) . showsPrec1 n v -- doesn't handle n correctly because that's not the point of the question and would only distract from the actual important idea

Show1 类（以及一些标准类型的实例）也可用于on Hackage。定义它的模块使用了一些扩展——但只是为了减少样板，而不是启用无聊的旧 Haskell2010 无法做的任何事情。

Answer 3

好的，所以在玩代码时，我发现了一种方法：

instance (Functor f, Show (f String)) => Show (Foobar f) where
  show = fold show

fold :: Functor f => (f x -> x) -> Foobar f -> x
fold f (Foo x) = f (fmap (fold f) x)

不过有几个问题。

• 它不会产生完全正确的输出。 （Foo 构造函数丢失，子表达式被引用。）
• 显然需要UndecidableInstances 才能工作。 (!)
• 我尝试将 show 更改为包含 Foo 构造函数，但随后 GHC 出现恐慌 (!!!)

我不知道您实际上可以通过编写用户代码来使 GHC 崩溃...显然您可以做到这一点。

ghc: panic! (the 'impossible' happened)
  (GHC version 7.4.2 for i386-unknown-mingw32):
    kindFunResult ghc-prim:GHC.Prim.*{(w) tc 34d}

Please report this as a GHC bug:  http://www.haskell.org/ghc/reportabug

我猜它被称为“不可判定”是有原因的！ o_O