在excel中从另一个单元格中查找单元格的单元格引用

Question

我有一个工作表，它从同一个工作簿 (=data!C68) 中的不同工作表返回一个值，该工作表返回一个值。

在另一个单元格中，我想引用原始单元格中的引用，但将行增加 1 - (=data!C69)。单元格不相邻。

这是否可以通过函数或 fromula 实现？

谢谢

乔纳森

Answer 1

Option Explicit
Function GetCellReferenceUsedInFormula(ByVal src As Range) As Range
If src.HasFormula Then
    Set GetCellReferenceUsedInFormula = Evaluate(Mid(src.Formula, 2))
End If
End Function

并在公式中使用上述函数OFFSET

=OFFSET(GetCellReferenceUsedInFormula(A1),1,0)

这是假设单元格 A1 包含公式 =data!C68。
请注意，VBA 代码假定公式很简单（即=somecellreference）。

Answer 2

有很多方法可以实现这一点。这是一种方法。我通过合并要偏移的行和列来扩展该功能。将此代码粘贴到模块中

语法

=GetOffset(Range,Row,Col)

备注

范围（必填）是具有公式的单元格

行（可选）要偏移的行

Col（可选）要偏移的列

示例用法

=GetOffset(A1) ：这将从 A1 所指的同一单元格中获取值。如果 A1 指的是=data!C69，那么 GetOffset 将从数据中获取价值！C69

=GetOffset(A1,1) ：这将从 A1 所指的下一个单元格（向下 1 行）获取值。如果 A1 指的是=data!C69，那么 GetOffset 将从数据中获取价值！C70

=GetOffset(A1,1,1) ：这将从 A1 所指的下一个单元格（跨 1 Col 向下 1 行）获取值。如果 A1 指的是=data!C69，那么 GetOffset 将从数据中获取价值！D70

=GetOffset(A1,0,1) ：这将从 A1 所指的下一个单元格（跨 1 Col 的同一行）获取值。如果 A1 指的是=data!C69，则 GetOffset 将从数据中获取值！D69

代码

Public Function GetOffset(Rng As Range, Rw As Long, Col As Long) As Variant
    Dim MyArray() As String, strTemp As String
    Dim TempRow As Long, TempCol As Long

    On Error GoTo Whoa

    Application.Volatile

    MyArray = Split(Rng.Formula, "!")

    TempRow = Range(MyArray(UBound(MyArray))).Row
    TempCol = Range(MyArray(UBound(MyArray))).Column

    TempRow = TempRow + Rw
    TempCol = TempCol + Col

    strTemp = MyArray(0) & "!" & Cells(TempRow, TempCol).Address

    GetOffset = Application.Evaluate(Trim(strTemp))
    Exit Function
Whoa:
End Function