带有表单数据的 VBA 发布请求（URL 不变）

Question

我遇到过许多类似的问题，例如this 和this，但我的问题要简单得多。我想更改网络表单上的日期并使用 POST 请求获取数据

我有这个发出 POST 请求的代码：

Sub winpost()
Dim WebClient As WinHttp.WinHttpRequest
Set WebClient = New WinHttp.WinHttpRequest
Dim searchResult As HTMLTextElement: Dim searchTxt As String
Dim html As New HTMLDocument

Dim Payload As String
Payload = "ContentPlaceHolder1_ddlday=6"

With WebClient
.Open "POST", "http://pib.nic.in/AllRelease.aspx", False
.setRequestHeader "Content-Type", "application/x-www-form-urlencoded"
.send (Payload)
.waitForResponse
End With

html.body.innerHTML = WebClient.responseText
Set searchResult = html.querySelector(".search_box_result"): searchTxt = searchResult.innerText
Debug.Print searchTxt

End Sub

网站是this。该页面发送一个关于任何字段更改的发布请求。 在查看网络 > Formdata 部分下的 ChromeDevTools 时，我看到了这个：

ctl00$ContentPlaceHolder1$ddlday: 8

我在 Payload 字符串中尝试了各种版本。但它总是返回相同的页面（1 月 8 日）。

Answer 1

Internet Explorer

由于没有 SelectByText 选项，IE 的语法与 selenium basic（显示在底部）略有不同。例如，您可以使用索引或属性 = 值 css 选择器。这里的月份是最多 12 个索引而不是月份名称

Option Explicit    
Public Sub SetDates()
    Dim ie As New InternetExplorer
    With ie
        .Visible = True
        .Navigate2 "http://pib.nic.in/AllRelease.aspx"

        While .Busy Or .readyState < 4: DoEvents: Wend

        With .Document
            .querySelector("#btnSave").Click
            .querySelector("#ContentPlaceHolder1_ddlMonth [value='2']").Selected = True
            .querySelector("#ContentPlaceHolder1_ddlYear [value='2018']").Selected = True
            .querySelector("#ContentPlaceHolder1_ddlday [value='2']").Selected = True
        End With
        Stop '<==delete me later
        .Quit
    End With
End Sub

---

基本硒：

如果您确实走selenium basic vba 路线，您可以执行如下操作。注意：安装 selenium 后，您需要转到 VBE > Tools > References > Add reference to selenium type library。您还需要最新的 Chrome 和 ChromeDriver，并且 ChromeDriver 文件夹应该放在环境路径中，或者 chromedriver 放在包含 selenium 可执行文件的文件夹中。

Option Explicit
Public Sub SetDates()
    Dim d As WebDriver
    Set d = New ChromeDriver
    Const Url = "http://pib.nic.in/AllRelease.aspx"
    With d
        .Start "Chrome"
        .get Url
        .FindElementById("btnSave").Click

        'date values
        .FindElementById("ContentPlaceHolder1_ddlMonth").AsSelect.SelectByText "February"
        .FindElementById("ContentPlaceHolder1_ddlYear").AsSelect.SelectByText "2018"
        .FindElementById("ContentPlaceHolder1_ddlday").AsSelect.SelectByText "2"
        Stop   'delete me later

        .Quit
    End With
End Sub