类型与工作表名称 VBA 不匹配

Question

我正在尝试编写一个简单的 VBA 代码，该代码在工作簿中运行，删除一些完整的工作表，并清除其他工作表的内容。这是我的代码：

Sub CleanSheets()
Dim x As Integer

x = 1
Do Until x = Sheets.Count
    If Sheets(x).Name = "MIR - Raw" Or "MRR - Raw" Or "MWR - Raw" Or "PL - Raw" Or "SHP - Raw" Then
    'clear them
        Sheets(x).ClearContents
    ElseIf Sheets(x).Name = "Dashboard" Then

    Else
        'delete the sheet
        Application.DisplayAlerts = False
        Sheets(x).Delete
        Application.DisplayAlerts = True
        x = x - 1
    End If
x = x + 1
Loop
End Sub

我在“if sheet(x).name = ...”行中不断收到类型不匹配。我对 Sheets.Names 对象不太熟悉，我怎么把类型搞砸了？

Answer 1

您的代码可以正常工作。只需将 If Sheets(x).Name = "MIR - Raw" 或 "MRR - Raw" 或 "MWR - Raw" 或 "PL - Raw" 或 "SHP - Raw" 更改为 If Sheets( x).Name = "MIR - Raw" 或 Sheets(x).Name = "MRR - Raw" 或 Sheets(x).Name = "MWR - Raw" 或 Sheets(x).Name = "PL - Raw" 或Sheets(x).Name = "SHP - Raw"

Sub CleanSheets()
Dim x As Integer

x = 1
Do Until x = Sheets.Count
    If Sheets(x).Name = "MIR - Raw" Or Sheets(x).Name = "MRR - Raw" Or Sheets(x).Name = "MWR - Raw" Or Sheets(x).Name = "PL - Raw" Or Sheets(x).Name = "SHP - Raw" Then
    'clear them
        Sheets(x).ClearContents
    ElseIf Sheets(x).Name = "Dashboard" Then

    Else
        'delete the sheet
        Application.DisplayAlerts = False
        Sheets(x).Delete
        Application.DisplayAlerts = True
        x = x - 1
    End If
x = x + 1
Loop
End Sub

Answer 2

@dee 的回答已解决您的问题，但我看到您检查的名称太多，我想为您的问题提供更优雅的解决方案。

这个想法很简单：将“If”和“else if”的情况转储到两个单独的数组中，并检查工作表名称是否在每个数组中，并采取相应的动作。由于ElseIf 子句中没有任何动作，我们可以只用If/ElseIf 重写逻辑。我利用this answer中的Jimmy Pena's函数IsInArray进行检查。

另外，我对代码进行了一些更改，使其更具可读性：

Sub CleanSheets()
    Dim x As Long   ' Long is safer and faster
    Dim aFirstCategory(4) As String
    Dim aSecondCategory(1) As String

    ' Note that checking for the sheet name is usually not very robust.
    ' You might be interested in the Like function to make your checks more flexible
    aFirstCategory(0) = "MIR - Raw"
    aFirstCategory(1) = "MRR - Raw"
    aFirstCategory(2) = "MWR - Raw"
    aFirstCategory(3) = "PL - Raw"
    aFirstCategory(4) = "SHP - Raw"

    aSecondCategory(0) = "Dahshboard"

    x = 1  ' I would check with ForEach wSheet in Sheets instead
    Do 'Until should go to the end of the loop, else the last sheet will not be checked
        If IsInArray(Sheets(x).Name, aFirstCategory) Then
        'clear them
            Sheets(x).Cells.ClearContents ' Sheets(x).ClearContents gives error I think
        ElseIf not IsInArray(Sheets(x).Name, aSecondCategory) Then
            'delete the sheet
            Application.DisplayAlerts = False
            Sheets(x).Delete
            Application.DisplayAlerts = True
            x = x - 1
        End If
        x = x + 1
    Loop Until x = Sheets.Count
End Sub

Function IsInArray(stringToBeFound As String, arr As Variant) As Boolean
  IsInArray = (UBound(Filter(arr, stringToBeFound)) > -1)
End Function