保存为 Outlook 文件夹路径的 VBA 代码引发运行时错误

Question

每月自动将 Outlook 收件箱中的特定电子邮件保存在硬盘上。

我希望能够每月自动保存 Outlook 收件箱中包含关键字“批准”或“已批准”且不区分大小写且由特定发件人发送的特定电子邮件。

1. 在为另存为提供的文件夹路径中出现错误
2. 我还想调整代码以使其每个月都能正常工作（例如在每个月的收件箱中可用电子邮件的日期之后运行宏 - 比如每月的第三周）
3. 我想调整代码以仅保存来自特定发件人、特定主题和特定内容的电子邮件

Option Explicit

Sub outlooksavefile()

    Dim o As Outlook.Application
    Set o = New Outlook.Application

    Dim ons As Outlook.Namespace
    Set ons = o.GetNamespace("mapi")

    Dim fol As Outlook.Folder
    Set fol = ons.GetDefaultFolder(olFolderInbox).Folders("Test")

    Dim omail As Outlook.MailItem
    Set omail = o.CreateItem(olMailItem)

    For Each omail In fol.Items
        omail.SaveAs "H:\2019" & omail.Subject & ".msg"
    Next omail

End Sub

Answer 1

您有责任确保文件名不包含无效字符（例如“:”或“\”） - 您的代码按原样使用邮件主题。

Answer 2

您必须通过检查其Class 来确保在您的文件夹中找到的每个项目都是一封电子邮件。

关于错误：也许您不允许在那里写信，或者 - 更有可能 - 电子邮件主题中的某些字符在您的文件系统中是被禁止的。我添加了一些代码来替换禁用字符。

如果您循环访问每封电子邮件，则无需在之前生成CreateItem 的其他新电子邮件。

Option Explicit

Sub outlooksavefile()
    Dim o As Outlook.Application
    Set o = New Outlook.Application

    Dim ons As Outlook.NameSpace
    Set ons = o.GetNamespace("mapi")

    Dim fol As Outlook.Folder
    Set fol = ons.GetDefaultFolder(olFolderInbox).Folders("Test")

    Dim omail As Object
    For Each omail In fol.Items
        If omail.Class = olMail Then  ' olMail = 43
            Debug.Print omail.Sender
            Debug.Print omail.Subject
            Debug.Print omail.Sender
            Debug.Print Left(omail.Body, 20)
            omail.SaveAs Environ("USERPROFILE") & "\Documents\" & _
                AllowedChars(omail.Subject) & ".msg", olMSG ' olMSG = 3
        End If
    Next omail
End Sub

Private Function AllowedChars(ByRef s As String) As String
    Dim i As Long
    Dim myChar As String
    AllowedChars = s
    For i = 1 To Len(AllowedChars)
        myChar = Mid$(AllowedChars, i, 1)
        If myChar Like "[<>:""/\|?*]" Or Asc(myChar) < 32 Then
            Mid$(AllowedChars, i, 1) = "_"
        End If
    Next i
End Function

关于您的问题 2：请在运行后提出另一个问题。

关于问题 3：我添加了一些调试信息以查看发件人和其他电子邮件项目的存储方式。基于此，您可能会生成一些 If 条件。