在 VBA for Word 中查找/替换字符限制解决方法

Question

我有一个基本的 vbscript 可以在 microsoft word 中查找和替换，但是我无法遍历一定数量的字符（我认为是 256）。我想知道是否有人知道解决此问题的方法。以下是我正在使用的脚本示例：

Sub FixedReplacements()
Dim Rng As Range
Dim SearchString As String
Dim EndString As String
Dim Id As String
Dim Link As String

Rng.Find.ClearFormatting
Rng.Find.Replacement.ClearFormatting
With Rng.Find
    .Text = "" 'find text won't exceed character limitation'
    .Replacement.Text = "" 'replace text won't exceed character limitation'
    .Forward = True
    .Wrap = wdFindContinue
    .Format = False
    .MatchCase = False
    .MatchWholeWord = False
    .MatchWildcards = False
    .MatchSoundsLike = False
    .MatchAllWordForms = False
End With
Rng.Find.Execute Replace:=wdReplaceAll   

Answer 1

要查找过长的文本，请搜索字符串的前 255 个字符，然后将找到的 Range 扩展到其他字符。或将字符串分解为 255 个字符的“位”并连续搜索它们（始终将第一个找到的范围扩展到每个后续找到的范围的终点）。

可以使用太长的文本进行替换，但不能使用Replace。相反，在循环中将字符串值分配给找到的范围。 （注意Wrap需要设置为wdFindStop。）示例

Dim bFound As Boolean
Dim replacementText as String
Dim findText as String, excessText as String
Dim excessChars as Long, bTooLong as Boolean

findText = "Text to be found..."
If Len(findText) > 255 Then
   bToolLong = True
   excessText = Mid(findText, 256)
   excessChars = Len(excessText)
   findText = Left(findText, 255)
End If
replacementText = "some long string greater than 256 characters"
With Rng.Find
    .Text = findText
    '.Replacement.Text = "" 'replace text won't exceed character limitation'
    .Forward = True
    .Wrap = wdFindStop
    .Format = False
    .MatchCase = False
    .MatchWholeWord = False
    .MatchWildcards = False
    .MatchSoundsLike = False
    .MatchAllWordForms = False
End With
bFound = Rng.Find.Execute
Do While bFound
    If bTooLong Then
      Rng.End = Rng.End + excessChars
      'Possible to check findText against the range
      'If Rng.Text <> findText Then 'do something
    End If
    Rng.Text = replacementText
    Rng.Collapse wdCollapseEnd
    bFound = Rng.Find.Execute
Loop

Answer 2

Find().Text 没有限制。检查这个：

Option Explicit

Sub TestMe()

    Dim myRange As Range
    Set myRange = ActiveDocument.Content

    Dim lookFor As String
    lookFor = "The text to be searched for. Use an empty string () to search for formatting only. You can search for special characters by specifying appropriate character codes. For example, corresponds to a paragraph mark and corresponds to a tab character."
    myRange.Find.Execute FindText:=lookFor, ReplaceWith:="hello", Replace:=wdReplaceAll

End Sub

• Word.Find

可能限制部分是a行，在要查找的字符串中没有正确解析，因此没有找到。

Answer 3

我花了很长时间寻找一个简单的解决方案；为了那些也拖网的人的利益，请考虑我的解决方案。

我的假设是要替换的文本出现一次。

1. 查找要替换的文本
2. 在之后插入新文本

3. 使用查找和替换，删除找到的文本

   With WordDoc.Content
   .Find.Execute findText:="text", Forward:=True, Wrap:=wdFindStop
   .InsertAfter Text:="newtext"
   .Find.Execute findText:="text", ReplaceWith:=""
   End With