VBA 宏，类型不匹配错误

Question

我正在尝试在 excel 中获取 JSON 数据并对其进行解析。但是，我收到一个错误：类型不匹配。

有谁知道我该如何解决这个问题？我无法弄清楚我做错了什么。

这是我正在使用的 API 的链接：https://min-api.cryptocompare.com/data/price?fsym=ETH&tsyms=USD

代码如下：

Public Sub exceljson()

    Dim https As Object, JSON As Object, i As Integer

    Set https = CreateObject("MSXML2.XMLHTTP")

    https.Open "GET", "https://min-api.cryptocompare.com/data/price?fsym=ETH&tsyms=USD", False
    https.Send

    Set JSON = ParseJson(https.responseText)
    i = 2

    For Each Item In JSON
        Sheets(1).Cells(i, 1).Value = Item("USD")
        i = i + 1
    Next

    MsgBox ("complete")

End Sub

Answer 1

如果您确认已正确导入JsonConverter 模块和Dictionary 类并引用Microsoft Scripting Runtime，则以下代码将起作用：

    Public Sub exceljson()
    Dim https As Object, Json As Object, i As Integer

    Dim Item As Variant

    Set https = CreateObject("MSXML2.XMLHTTP")
    https.Open "GET", "https://min-api.cryptocompare.com/data/price?fsym=ETH&tsyms=USD", False
    https.Send

    Set Json = JsonConverter.ParseJson(https.responseText)

    i = 2
    For Each Item In Json.Items
        Sheets(1).Cells(i, 1).Value = Item
        i = i + 1
    Next
    MsgBox ("complete")
End Sub

希望对你有帮助！

---

更新

你应该分析服务器响应的Json数据，“Data”的值是一个Dictionary。所以你应该在For Each Loop中使用字典。

以下代码将获取所有数据，我只是以“高”键为例。您可以轻松地将其他键输出到 excel 中。

Public Sub exceljson()
    Dim https As Object, Json As Object, DataItem As Dictionary, i As Integer


    Set https = CreateObject("MSXML2.XMLHTTP")
    https.Open "GET", "https://min-api.cryptocompare.com/data/histominute?fsym=BTC&tsym=USD&limit=60&aggregate=3&e=CCCAGG", False
    https.Send

    'Use this debug command to see the whole response text
    'Debug.Print https.responseText
    Set Json = JsonConverter.ParseJson(https.responseText)


    i = 2
    For Each DataItem In Json("Data")
        'Use "high" as example, you can output other key/values
        Sheets(1).Cells(i, 1).Value = DataItem("high")

        i = i + 1
    Next
    MsgBox ("complete")
End Sub