数组 CountIf 替换 - Count(Match())

Question

核心问题

如何尽可能高效地（从性能方面）在一个范围内重复执行CountIf()s？

详细问题

范围到数组

由于对电子表格的每次读/写都会导致 VBA 代码变慢，因此建议尽可能少地这样做。通常情况下，如果有人重复读/写某个范围，他或她应该首先将该范围保存到一个数组中，对数组执行操作，然后在必要时对电子表格进行最后的读取或写入。

示例值和代码

如何在上面的A2:A11 范围内使用执行CountIf()s 来计算每个值的计数并将它们写入D2:D7？我希望下面的代码可以工作：

Sub M1ArrayCount()

Dim arrNumbers() As Variant
Dim Long1 As Long
Dim Loop1 As Long

arrNumbers() = ThisWorkbook.Sheets(1).Range("A2:A11").Value

With ThisWorkbook.Sheets(1)
    For Loop1 = 1 To 6
        .Cells(Loop1 + 1, 4).Value = Application.CountIf(arrNumbers(), Loop1)
    Next Loop1
End With

End Sub

CountIf() 不适用于数组

但是，因为Application.CountIf() 仅适用于范围而不适用于数组，所以D2:D7 在运行上述代码后都会显示#VALUE! 错误。必须找到替代品。

Answer 1

解决方案 - 计数（匹配（））

我们正在寻找的解决方案是：

Application.Count(Application.Match(SavedArray(), Array([lookup_value]), 0))

什么？这是如何运作的？ --- 通常返回行号的函数如何与数组和计数配对以返回正确答案？你如何计算行号？

力学解释

非常感谢@Jeeped，下面是它的工作原理：

Match(lookup value, lookup array, 0) 的一个未记录的功能是，如果您将数组作为查找值，它会将Match() 您输入的数组中的每个值与查找数组对应。因此，对于上面的示例，对于Loop = 1，它将变为：

{match(A2, Array("1"), 0),match(A3, Array("1"), 0), ... match(A11, Array("1"), 0)}

然后，根据@Jeeped：

每次匹配都会返回一个数字或一个错误。 Count() 函数计算数字，而不是错误。因此，您可以计算A1:A11 中的任何值是否与Loop1 匹配。

最终代码和价值观

Sub M1ArrayCount()

Dim arrNumbers() As Variant
Dim Long1 As Long
Dim Loop1 As Long

arrNumbers() = ThisWorkbook.Sheets(1).Range("A2:A11").Value

With ThisWorkbook.Sheets(1)
    For Loop1 = 1 To 6
        .Cells(Loop1 + 1, 4).Value = Application.Count(Application.Match(arrNumbers(), Array(Loop1), 0))
    Next Loop1
End With

End Sub

参考 --- This comment

This answer

问题

例子：

myarray = array("First","Second","Second","Third","Fourth")

那么countif(myarray,"second") 语法是什么？ （结果 应该等于 2 个计数）

回答

也可以试试：

MsgBox Application.Count(Application.Match(myArray, Array("Second"), 0))

This chat

Answer 2

Dim rowin as integer 'this is a counter for the row index
For rowin = 2 To Sheets("Sheet1").UsedRange.Rows.Count
Sheets("Sheet1").Range("D" & rowin).Value = WorksheetFunction.CountIf(Range("A:A"), Range("C" & rowin))
Next