如何防止在 Form_Delete 事件中重复触发 MsgBox？

Question

我有一个数据表表单，它使用户可以轻松选择所有记录并删除。我想写一个 VBA 代码来防止用户在选择超过 20 条记录时删除记录。然后我写了这段代码，但问题是每条记录都会触发消息。有人遇到过这个吗？请看下文。

  Private Sub Form_Delete(Cancel As Integer)
  If Me.SelHeight > 20 Then
      Cancel = True
      MsgBox ("Bulk deletion is not allowed!")
 End If
 End Sub

Answer 1

如果您对BeforeDelConfirm event 没有被解雇感到困惑，就像我得到的那样，请检查Confirm Record ChangesOption 是否已设置。如果不是，则不会引发事件。

使用BeforeDelConfirmandAfterDelConfirm，这个任务就简单多了。

在表单模块之上

Option Explicit

Dim deleteCount As Long
Private Const MaxDeleteRows As Long = 20 ' set this constant to the number of rows that can be deleted at once

事件代码：

Private Sub Form_AfterDelConfirm(Status As Integer)
  If deleteCount > MaxDeleteRows Then
    MsgBox ("Bulk deletion is not allowed!")
  End If
  deleteCount = 0
End Sub

Private Sub Form_BeforeDelConfirm(Cancel As Integer, Response As Integer)
  If deleteCount > MaxDeleteRows Then
    Cancel = True
  End If
  Response = acDataErrContinue
End Sub

Private Sub Form_Delete(Cancel As Integer)
  If deleteCount = 0 Then
    deleteCount = Me.SelHeight
  End If
End Sub

Private Sub Form_Deactivate()
 ' Application.SetOption "Confirm Record Changes", False ' needed if you want to have Confirm Record Changes off elsewhere
End Sub

Private Sub Form_Activate()
 ' Application.SetOption "Confirm Record Changes", True ' needed if you want to have Confirm Record Changes off elsewhere (turns it on here)
End Sub