运行时错误 1004 - 更新数据透视表的宏

Question

我正在尝试使用宏更新数据透视表，因为每个月都会将数据添加到表的底部（更新以将数据包含到最后一行）。

Option Explicit

Sub Pivot()

Dim shConD As Worksheet
Dim shPvtTbl As Worksheet
Dim lr As Long
Dim rng As Range

Set shConD = ActiveWorkbook.Sheets("Consolidated_Data")
Set shPvtTbl = ActiveWorkbook.Sheets("PivotTables")

lr = shConD.Range("A" & Rows.Count).End(xlUp).Row
Set rng = shConD.Range("A1:F" & lr)

With shPvtTbl.PivotTables(3).PivotCache
     .SourceData = rng.Address(True, True, xlR1C1, True) 'Error appears here
     .Refresh
End With

End Sub

在.SourceData 行，我收到运行时错误 1004、应用程序定义或对象定义错误。遵循此 thread 和后续 chat 的逻辑。在此先感谢各位。

Answer 1

如果您使用 Excel 2007 或更高版本，那么完成此操作的最简单方法是确保您的数据透视表源数据是 Excel 表（又名 ListObject），并使用更改数据透视表数据源中的表名称，如图所示下面。

多亏了表格的魔力，从那时起，每当您向表格添加新数据时，表格都会自动展开。每当您刷新数据透视表时，它总是会自动获取新数据。无需再更改数据透视表数据源。

Answer 2

试试下面的代码（代码的 cmets 中的解释）：

Option Explicit

Sub Pivot()

Dim shConD As Worksheet
Dim shPvtTbl As Worksheet
Dim lr As Long
Dim rng As Range

' Added PivotTable variables
Dim PvtTbl As PivotTable
Dim PvtCache As PivotCache

Set shConD = ActiveWorkbook.Sheets("Consolidated_Data")
Set shPvtTbl = ActiveWorkbook.Sheets("PivotTables")

lr = shConD.Range("A" & shConD.Rows.Count).End(xlUp).Row
Set rng = shConD.Range("A1:F" & lr)

' set/update the PivotCache (with latest rng modifications
Set PvtCache = ActiveWorkbook.PivotCaches.Create(SourceType:=xlDatabase, SourceData:=rng.Address(False, False, xlA1, xlExternal))
' for DEBUG Only
Debug.Print PvtCache.SourceData

' set the PivotTable object
Set PvtTbl = shPvtTbl.PivotTables(3)
' for DEBUG Only
Debug.Print PvtTbl.Name

' refresh the PivotTable with the updated PivotCache
PvtTbl.ChangePivotCache PvtCache
PvtTbl.RefreshTable

End Sub