宏只会在调试模式下创建超链接

Question

这是一个宏，它将搜索单个目录中包含的所有工作簿的所有工作表中的所有单元格。除了添加超链接方法外，一切都像宣传的那样工作，如果我反复混合 F8，它确实有效。

如何编辑宏以使超链接部分正常工作？

'Search all workbooks in a folder for string
Sub SearchWorkbooks()
Dim fso As Object
Dim fld As Object
Dim strSearch As String
Dim strPath As String
Dim strFile As String
Dim wOut As Worksheet
Dim wbk As Workbook
Dim wks As Worksheet
Dim Lrow As Long
Dim rFound As Range
Dim strFirstAddress As String

On Error GoTo ErrHandler
Application.ScreenUpdating = False

strSearch = "Capacitor"
strPath = "C:\!Source"

Set wOut = Worksheets.Add
Lrow = 1
With wOut
    .Name = "Results"
    .Cells(Lrow, 1) = "Workbook"
    .Cells(Lrow, 2) = "Worksheet"
    .Cells(Lrow, 3) = "Cell"
    .Cells(Lrow, 4) = "Text in Cell"
    .Cells(Lrow, 5) = "Link"
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set fld = fso.GetFolder(strPath)

    strFile = Dir(strPath & "\*.xls*")
    Do While strFile <> ""
        Set wbk = Workbooks.Open _
          (Filename:=strPath & "\" & strFile, _
          UpdateLinks:=0, _
          ReadOnly:=True, _
          AddToMRU:=False)

        For Each wks In wbk.Worksheets
            Set rFound = wks.UsedRange.Find(strSearch)
            If Not rFound Is Nothing Then
                strFirstAddress = rFound.Address
            End If
            Do
                If rFound Is Nothing Then
                    Exit Do
                Else
                    Lrow = Lrow + 1
                    .Cells(Lrow, 1) = wbk.Name
                    .Cells(Lrow, 2) = wks.Name
                    .Cells(Lrow, 3) = rFound.Address
                    .Cells(Lrow, 4) = rFound.Value

                    'This is the line that does not work
                    'well it actually works in debug mode but not in real time
                    wks.Hyperlinks.Add Anchor:=Cells(Lrow, 5), Address:=wbk.FullName, SubAddress:= _
                                    wks.Name & "!" & rFound.Address, TextToDisplay:="Link"

                End If
                Set rFound = wks.Cells.FindNext(After:=rFound)
            Loop While strFirstAddress <> rFound.Address
        Next

        wbk.Close (False)
        strFile = Dir
    Loop
    .Columns("A:D").EntireColumn.AutoFit
End With
'MsgBox "Done"    

ExitHandler:
Set wOut = Nothing
Set wks = Nothing
Set wbk = Nothing
Set fld = Nothing
Set fso = Nothing
Application.ScreenUpdating = True
Exit Sub

ErrHandler:
MsgBox Err.Description, vbExclamation
Resume ExitHandler
End Sub

Answer 1

尝试将工作表引用添加到您的 Cells() 调用中，例如 wks.Cells(......)